Flash Workshop

Flash file uploader with progress bar

2011-02-13T22:38:00.000-08:00

Download fileUploadFlashWorkshop.zip, 515 KB(Flash CS5 professional)

ActionScript Code:





/********************************

Developed by Anil kumar N D

anilkumarnd@gmail.com

Flash Professional CS5

ActionScript 3.0

14 February 2011

*********************************/




package  {

import flash.display.MovieClip;

import flash.net.FileReference;

import flash.events.*;

import flash.net.URLRequest;

import flash.net.URLVariables;




public class upload extends MovieClip {




 private var _file:FileReference;





 /*******************************************************************************

 Default constructor

 ********************************************************************************/

 public function upload() {
 
  this.addEventListener(Event.ENTER_FRAME,fn_enterFrameHandler);

 }




 /*******************************************************************************

 This function is a ENTER_FRAME event handler of "this"

 input

 IN_Event : Event

 ********************************************************************************/

 private function fn_enterFrameHandler(IN_Event:Event):void{
 
  if(this.loaderInfo.bytesTotal == this.loaderInfo.bytesLoaded){
  
   this.removeEventListener(Event.ENTER_FRAME,fn_enterFrameHandler);
  
   _file = new FileReference;
  
   _file.addEventListener(Event.CANCEL, fn_cancelHandler);
  
   _file.addEventListener(Event.COMPLETE, fn_completeHandler);
  
   _file.addEventListener(HTTPStatusEvent.HTTP_STATUS, fn_httpStatusHandler);
  
   _file.addEventListener(IOErrorEvent.IO_ERROR, fn_ioErrorHandler);
  
   _file.addEventListener(Event.OPEN, fn_openHandler);
  
   _file.addEventListener(ProgressEvent.PROGRESS, fn_progressHandler);
  
   _file.addEventListener(SecurityErrorEvent.SECURITY_ERROR, fn_securityErrorHandler);
  
   _file.addEventListener(Event.SELECT, fn_selectHandler);
  
   _file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,fn_uploadCompleteDataHandler);
  
   btn_browse.addEventListener(MouseEvent.CLICK,fn_browserClickHandler);
  
   btn_upload.addEventListener(MouseEvent.CLICK,fn_uploadClickHandler);
  
   btn_cancel.addEventListener(MouseEvent.CLICK,fn_cancelClickHandler);
  
   mc_progressBar.mc_bar.scaleX = 0; 
 
  
  }
 
 
 }




 /*******************************************************************************

 This function is a click event handler of btn_browse

 input

 IN_Event : MouseEvent

 ********************************************************************************/

 private function fn_cancelClickHandler(IN_Event:MouseEvent):void{
 
  _file.cancel();
 
  mc_progressBar.mc_bar.scaleX = 0;
 
  btn_upload.enabled = false;
 
  btn_browse.enabled = true;
 
  btn_cancel.enabled = false; 
 
  txt_server.text = "File upload cancelled";

 } 




 /*******************************************************************************

 This function is a click event handler of btn_browse

 input

 IN_Event : MouseEvent

 ********************************************************************************/

 private function fn_uploadClickHandler(IN_Event:MouseEvent):void{
 
  btn_upload.enabled = false;
 
  btn_browse.enabled = false;
 
  btn_cancel.enabled = true;
 
  _file.upload(new URLRequest("fileUpload.php"));
 

 } 




 /*******************************************************************************

 This function is a click event handler of btn_browse

 input

 IN_Event : MouseEvent

 ********************************************************************************/

 private function fn_browserClickHandler(IN_Event:MouseEvent):void{
 
  _file.browse();
 
  txt_server.text = "Select your file";


 }




 /*******************************************************************************

 These functions are the event handlers of _file

 ********************************************************************************/

 private function fn_cancelHandler(IN_Event:Event):void {
 
           trace("cancelHandler: " + IN_Event);
 
       }

       private function fn_completeHandler(IN_Event:Event):void {
 
           trace("completeHandler: " + IN_Event);
 
  btn_cancel.enabled = false;
 
  btn_browse.enabled = true;
 
  mc_progressBar.mc_bar.scaleX = 0;
 
       }

       private function fn_uploadCompleteDataHandler(IN_Event:DataEvent):void {
 
           trace("uploadCompleteData: " + IN_Event);
 
   var variables:URLVariables = new URLVariables(IN_Event.data);
  
   txt_server.text = variables.dataFromServer;

       }

       private function fn_httpStatusHandler(IN_Event:HTTPStatusEvent):void {
 
           trace("httpStatusHandler: " + IN_Event);
 
       }
      
       private function fn_ioErrorHandler(IN_Event:IOErrorEvent):void {
 
           trace("ioErrorHandler: " + IN_Event);
 
       }

       private function fn_openHandler(IN_Event:Event):void {
 
           trace("openHandler: " + IN_Event);
 
       }

       private function fn_progressHandler(IN_Event:ProgressEvent):void {
 
           trace("progressHandler name=" + _file.name + " bytesLoaded=" + IN_Event.bytesLoaded + " bytesTotal=" + IN_Event.bytesTotal);
 
  mc_progressBar.mc_bar.scaleX = IN_Event.bytesLoaded/IN_Event.bytesTotal;
 
  txt_server.text = "Uploading "+ int((IN_Event.bytesLoaded/IN_Event.bytesTotal)*100) + "%";
       }

       private function fn_securityErrorHandler(IN_Event:SecurityErrorEvent):void {
 
           trace("securityErrorHandler: " + IN_Event);
 
       }

       private function fn_selectHandler(IN_Event:Event):void {
 
  txt_filename.text = _file.name;
 
  btn_upload.enabled = true;
 
  txt_server.text = "You have selected '"+_file.name+"'";

 
       } 



}

}

Sending Email from Flash using PHP

2010-07-07T00:04:00.000-07:00

Download mailFromFlash.zip, 958 KB(Flash CS4 professional)

ActionScript Code:





/**************************************

Developed by

Anil kumar N D

anilkumarnd@gmail.com

http://flash-workshop.blogspot.com/

http://flash-workshop.com/


Flash CS4 professional

ActionScript 3.0

07 July,2010

**************************************/




package {

 import flash.display.MovieClip;
 
 import flash.net.URLLoader;
 
 import flash.net.URLRequest;
 
 import flash.net.URLRequestMethod;
 
 import flash.net.URLVariables;
 
 import flash.events.Event;
 
 import flash.events.MouseEvent;
 
 
 
 
 public class main extends MovieClip{
  
  private var ldr_receive:URLLoader;
  
  private var ldr_send:URLLoader;
  
  private var url_variables:URLVariables;
  
  private var urlRequest:URLRequest;
  
  
  
  
  /***********************************************************************************************
  
  Default constructor
  
  ************************************************************************************************/
  
  public function main():void {

  
   mc_send.mouseChildren = false;
   
   mc_send.buttonMode = true;
   
   mc_send.addEventListener(MouseEvent.CLICK,fn_mc_sendClickHandler);
   
   
   mc_cancel.mouseChildren = false;
   
   mc_cancel.buttonMode = true;
   
   mc_cancel.addEventListener(MouseEvent.CLICK,fn_mc_sendClickHandler);

   
   txt_name.tabIndex = 1;
   
   txt_subject.tabIndex = 2;
     
   txt_emailS.tabIndex = 3;
     
   txt_emailR.tabIndex = 4;
     
   txt_msg.tabIndex = 5;
 
   

  }
  
  
  
  
  /***********************************************************************************************
  
  
  
  ************************************************************************************************/
  
  private function fn_mc_sendClickHandler(IN_Event:Event):void {  
 
   switch(true){
    
    case(IN_Event.target.name == "mc_send" && (txt_name.text != "" && txt_emailS.text != "" && txt_emailR.text != "" && txt_subject.text != ""&& txt_msg.text != "")):
     
     urlRequest = new URLRequest("flashMail.php");
     
     url_variables = new URLVariables();
     
     url_variables.name = txt_name.text;
     
     url_variables.subject = txt_subject.text;
     
     url_variables.emailSender =  txt_emailS.text;
     
     url_variables.emailReceiver =  txt_emailR.text;
     
     url_variables.message = txt_msg.text;

     urlRequest.method=URLRequestMethod.POST;
   
     urlRequest.data=url_variables;
   
     ldr_send = new URLLoader();
   
     ldr_send.addEventListener(Event.COMPLETE, fn_serverResponse);
   
     ldr_send.load(urlRequest);
    
     break;
     
    case(IN_Event.target.name == "mc_cancel"):
    
     txt_status.text= "";
     
     txt_name.text = "";
     
     txt_emailS.text = "";
       
     txt_emailR.text = "";
       
     txt_msg.text = "";
     
     txt_subject.text = "";
    
     break;
     
    
   }

  }
  
  
  
  
  /***********************************************************************************************
  
  
  
  ************************************************************************************************/
  
  private function fn_serverResponse(IN_Event:Event):void {

   txt_name.text = "";
     
   txt_emailS.text = "";
     
   txt_emailR.text = "";
     
   txt_msg.text = "";
   
   txt_subject.text = "";
   
   ldr_receive = URLLoader(IN_Event.target);
   
   url_variables = new URLVariables(ldr_receive.data);

   txt_status.text= url_variables.returnValue;


  }
  
  
  
  
 }

}

Guestbook in Flash with AS3, MySQL and PHP

2010-07-06T05:20:00.000-07:00

Download AS3_MySQL_GuestBook.zip, 915 KB(Flash CS4 professional)

ActionScript Code:





/**************************************

Developed by

Anil kumar N D

anilkumarnd@gmail.com

http://flash-workshop.blogspot.com/

http://flash-workshop.com/


Flash CS4 professional

ActionScript 3.0

06 July,2010

**************************************/




package {

 import flash.display.MovieClip;
 
 import flash.net.URLLoader;
 
 import flash.net.URLRequest;
 
 import flash.net.URLRequestMethod;
 
 import flash.net.URLVariables;
 
 import flash.events.Event;
 
 import flash.events.MouseEvent;
 
 
 
 
 public class main extends MovieClip{
  
  private var ldr_receive:URLLoader;
  
  private var ldr_send:URLLoader;
  
  private var url_variables:URLVariables;
  
  private var xml_obj:XML;
  
  private var int_counter:int;
  
  private var urlRequest:URLRequest;
  
  
  
  
  /***********************************************************************************************
  
  Default constructor
  
  ************************************************************************************************/
  
  public function main():void {
   
   mc_ctrls.visible = false;
   
   txt_msgs.text = "Loading";
   
   ldr_receive = new URLLoader  ;

   ldr_receive.addEventListener(Event.COMPLETE,fn_serverResponse);
       
   ldr_receive.load(new URLRequest("getData.php"));
   
   mc_btn.mouseChildren = false;
   
   mc_btn.buttonMode = true;
   
   mc_btn.addEventListener(MouseEvent.CLICK,fn_mc_btnClickHandler);
   
   
   
   mc_ctrls.mc_send.mouseChildren = false;
   
   mc_ctrls.mc_send.buttonMode = true;
   
   mc_ctrls.mc_send.addEventListener(MouseEvent.CLICK,fn_mc_sendClickHandler);
   
   
   mc_ctrls.mc_cancel.mouseChildren = false;
   
   mc_ctrls.mc_cancel.buttonMode = true;
   
   mc_ctrls.mc_cancel.addEventListener(MouseEvent.CLICK,fn_mc_sendClickHandler);

  }
  
  
  
  
  /***********************************************************************************************
  
  
  
  ************************************************************************************************/
  
  private function fn_mc_sendClickHandler(IN_Event:Event):void {  
  
   mc_ctrls.visible = false;

   txt_msgs.visible = true;
   
   mc_btn.visible = true;
   
 
   switch(true){
    
    case(IN_Event.target.name == "mc_send" && (mc_ctrls.txt_name.text != "" && mc_ctrls.txt_email.text != "" && mc_ctrls.txt_msg.text != "")):
     
     urlRequest = new URLRequest("update.php");
     
     url_variables = new URLVariables();
     
     url_variables.name = mc_ctrls.txt_name.text;
     
     url_variables.email =  mc_ctrls.txt_email.text;
     
     url_variables.message = mc_ctrls.txt_msg.text;

     urlRequest.method=URLRequestMethod.POST;
   
     urlRequest.data=url_variables;
   
     ldr_send = new URLLoader();
   
     ldr_send.addEventListener(Event.COMPLETE, fn_serverResponse2);
   
     ldr_send.load(urlRequest);
    
     break;
     
    case(IN_Event.target.name == "mc_cancel"):
    
     trace("do something");
    
     break;
     
    
   }

  }
  
  
  
  
  /***********************************************************************************************
  
  
  
  ************************************************************************************************/
  
  private function fn_serverResponse2(IN_Event:Event):void {

   ldr_receive.load(new URLRequest("getData.php"));

  }
  
  
  
  
  /***********************************************************************************************
  
  
  
  ************************************************************************************************/
  
  private function fn_mc_btnClickHandler(IN_Event:Event):void {  
  
   mc_ctrls.visible = true;

   txt_msgs.visible = false;
   
   mc_btn.visible = false;
   
   mc_ctrls.txt_name.text = "";
   
   mc_ctrls.txt_email.text = "";
   
   mc_ctrls.txt_msg.text = "";

  }
  
  
  
  
  /***********************************************************************************************
  
  
  
  ************************************************************************************************/
  
  private function fn_serverResponse(IN_Event:Event):void {
   
   txt_msgs.text = "";

   url_variables = new URLVariables(IN_Event.target.data);
   
   xml_obj = new XML(String(url_variables.dataFromPhp));
   
   int_counter = xml_obj.Visitor.length();
   
   for each (var item:XML in xml_obj..Visitor) {
    
    txt_msgs.appendText("MSG: ");
    
    txt_msgs.appendText(String(int_counter--));

    txt_msgs.appendText("\n");
    
    txt_msgs.appendText(item.Message);
    
    txt_msgs.appendText("\n");
    
    txt_msgs.appendText("");
    
    txt_msgs.appendText(item.Name);
    
    txt_msgs.appendText("\n");
    
    txt_msgs.appendText(item.ip);
    
    txt_msgs.appendText("\n");
    
    txt_msgs.appendText(item.Date);
    
    txt_msgs.appendText("\n--------------------------------------------------------------------------------------\n");
    
   }
   
  }


 }

}

Control a car (MovieClip) with arrow keys for games, ActionScript 3.0

2010-04-29T00:36:00.000-07:00

Download car.zip, 496 KB(Flash CS4 professional)

ActionScript Code:





/**************************************

Developed by

Anil kumar N D

anilkumarnd@gmail.com

http://flash-workshop.blogspot.com/



Flash CS4 professional

ActionScript 3.0

29 April,2010


**************************************/




package {

import flash.display.MovieClip;

import flash.events.KeyboardEvent;

import flash.events.Event;




public class car extends MovieClip {




 /***********************************************************************************************

 Default constructor

 ************************************************************************************************/

 public function car():void {
 
  stage.frameRate = 30;

  mc_car.left = false;
 
  mc_car.up = false;
 
  mc_car.right = false;
 
  mc_car.down = false;
 
  mc_car.xFactor = 0;
 
  mc_car.yFactor = 0;
 
  mc_car.speed = 3;
 
  stage.addEventListener(KeyboardEvent.KEY_DOWN,fn_keyDownHandler);
 
  stage.addEventListener(KeyboardEvent.KEY_UP,fn_keyUpHandler);
 
  stage.addEventListener(Event.ENTER_FRAME,fn_enterFrameHandler);

 }




 /***********************************************************************************************



 ************************************************************************************************/

 private function fn_enterFrameHandler(IN_Event:Event):void {
 
 
  switch(mc_car.up){
  
   case(true):
  
    mc_car.y -= mc_car.yFactor;
   
    mc_car.x -= mc_car.xFactor;
   
    switch(mc_car.right){
    
     case(true):
   
      mc_car.rotation += mc_car.speed/2;
    
      break;
    
    }
   
    switch(mc_car.left){
    
     case(true):
   
      mc_car.rotation -= mc_car.speed/2;
    
      break;
    
    }
  
    break;
   
  }
 
  switch(mc_car.down){
  
   case(true):
  
    mc_car.y += mc_car.yFactor;
   
    mc_car.x += mc_car.xFactor;
   
    switch(mc_car.right){
    
     case(true):
   
      mc_car.rotation -= mc_car.speed/2;
    
      break;
    
    }
   
    switch(mc_car.left){
    
     case(true):
   
      mc_car.rotation += mc_car.speed/2;
    
      break;
    
    }
  
    break;
   
  }

  mc_car.yFactor = (-(((Math.abs(mc_car.rotation))/(90/mc_car.speed))-mc_car.speed));

  mc_car.xFactor = (((Math.abs(mc_car.rotation-90))/(90/mc_car.speed))-(mc_car.speed));
 
  switch(true){
  
   case (mc_car.xFactor > mc_car.speed):
  
    mc_car.xFactor = mc_car.speed - (mc_car.xFactor -mc_car.speed );
  
    break;
   
  }
 
 }




 /***********************************************************************************************



 ************************************************************************************************/

 private function fn_keyDownHandler(IN_Event:KeyboardEvent):void {

  switch(IN_Event.keyCode){
  
   case 37:
  
    mc_car.left = true;
   
    break;
   
   case 38:
  
    mc_car.up = true;
   
    break;
   
   case 39:
  
    mc_car.right = true;
   
    break;
   
   case 40:
  
    mc_car.down = true;
   
    break;
  
  }
 

 }




 /***********************************************************************************************



 ************************************************************************************************/

 private function fn_keyUpHandler(IN_Event:KeyboardEvent):void {

  switch(IN_Event.keyCode){
  
   case 37:
  
    mc_car.left = false;
   
    break;
   
   case 38:
  
    mc_car.up = false;
   
    break;
   
   case 39:
  
    mc_car.right = false;
   
    break;
   
   case 40:
  
    mc_car.down = false;
   
    break;
  
  }  
 
 }



}

}

Flash CS3 XML Menu, ActionScript 3.0

2009-10-14T05:44:00.000-07:00

Download XMLmenu.zip, 9 KB (Flash CS3 professional)

ActionScript Code:


 
/**************************************
Developed by Anil kumar N D
anilkumarnd@gmail.com
Flash CS4 professional
ActionScript 3.0
14 October,2009
http://flash-workshop.blogspot.com/
**************************************/
 
package {
 import flash.display.MovieClip;

   import flash.net.URLLoader;

   import flash.net.URLRequest;

import flash.events.Event;

import flash.text.TextField;

import flash.text.TextFieldAutoSize;

import flash.events.MouseEvent;
 public class xmlMenu extends MovieClip {

 private var mc_menuHolder:MovieClip;

 private var xml_Object:XML;

 private var ldr_loader:URLLoader;

 private var uin_i:uint;

 private var txt_status:TextField;

 private var arr_menuItem:Array;

 private var unt_currentID:uint;

 private var mc_currentMenu:MovieClip;




 /***********************************************************************************************

 Default constructor

 ************************************************************************************************/

 public function xmlMenu():void {
 
  stage.frameRate = 30;
 
  XML.prettyPrinting = false;
 
  arr_menuItem = new Array();
 
  ldr_loader = new URLLoader();
 
  ldr_loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);
 
  ldr_loader.load(new URLRequest("xmlMenu.xml"));
 
  txt_status = new TextField();
 
  addChild(txt_status);
 
  txt_status.y = 200;
 
  txt_status.width = 300;
 }




 /***********************************************************************************************

 This function is an event handler for complete event of ldr_loader

 After that it will build the menu and its listeners.

 INPUT :

 IN_Event -  Event

 ************************************************************************************************/

 private function loaderCompleteHandler(IN_Event:Event):void {
 
  mc_menuHolder = new MovieClip();
            xml_Object =  XML(ldr_loader.data);
 
  uin_i = 0;
   
  for each (var item:XML in xml_Object..mainMenu) {
    
   var mc_menu:MovieClip = createMenuItem(30,100,0xFF9900,5);
  
   TextField(mc_menu.getChildAt(0)).htmlText = item.caption;
  
   mc_menu.id = uin_i;
  
   mc_menu.control = "Menu";
  
   mc_menu.x = (uin_i)*mc_menu.width;
  
   mc_menu.addEventListener(MouseEvent.CLICK,clickHandler);
  
   mc_menu.addEventListener(MouseEvent.MOUSE_OVER,overHandler);
  
   mc_menu.addEventListener(MouseEvent.MOUSE_OUT,outHandler);
  
   var mc_subMenu:MovieClip = new MovieClip();
  
   mc_subMenu.name = "mc_subMenu_"+uin_i++;
 
   for(var uin_j:uint = 0 ; uin_j<item.item.length();uin_j++){
   
    var mc_menuItem:MovieClip = createMenuItem(30,100,0xFFFFCD,5);
   
    TextField(mc_menuItem.getChildAt(0)).htmlText = item.item[uin_j].caption;
   
    mc_menuItem.y = (uin_j+1)*mc_menuItem.height;
   
    mc_menuItem.addEventListener(MouseEvent.CLICK,clickHandler);
   
    mc_menuItem.addEventListener(MouseEvent.MOUSE_OVER,overHandler);
  
    mc_menuItem.addEventListener(MouseEvent.MOUSE_OUT,outHandler);
   
    mc_subMenu.addChild(mc_menuItem);
   
   }
  
   mc_subMenu.visible = false;
  
   mc_subMenu.x = mc_menu.x;
  
   mc_menuHolder.addChild(mc_subMenu);
  
   mc_menuHolder.addChild(mc_menu);
    
  }
 
  addChild(mc_menuHolder);
 
  mc_menuHolder.x = (stage.stageWidth/2) - (mc_menuHolder.width/2);
 
  mc_menuHolder.y=10;
   
       }




 /***********************************************************************************************

 This function is an event Handler for click event on all menus and its sub menus

 INPUT :

 IN_Event - MouseEvent

 ************************************************************************************************/

 private function clickHandler(IN_Event:MouseEvent):void{
 

  //trace(TextField(IN_Event.target.getChildAt(0)).text);
 
  txt_status.text = "You have selected "+TextField(IN_Event.target.getChildAt(0)).text;
 
  if(IN_Event.target.control == "Menu"){
  
   unt_currentID = IN_Event.target.id;
  
   mc_currentMenu = MovieClip(IN_Event.target);
  
   mc_menuHolder.getChildByName("mc_subMenu_"+unt_currentID).visible = true;
  
   arr_menuItem.splice(0,arr_menuItem.length);
  
   for(var uin_j:uint = 0 ; uin_j<MovieClip(mc_menuHolder.getChildByName("mc_subMenu_"+unt_currentID)).numChildren;uin_j++){
   
    arr_menuItem.push(MovieClip(mc_menuHolder.getChildByName("mc_subMenu_"+unt_currentID)).getChildAt(uin_j));
   
   }
  
  }
 
 }




 /***********************************************************************************************

 This function is an event Handler for MOUSE_OVER event on all menus and its sub menus

 INPUT :

 IN_Event - MouseEvent

 ************************************************************************************************/

 private function overHandler(IN_Event:MouseEvent):void{
 
  IN_Event.target.MouseOver = true;
  }




 /***********************************************************************************************

 This function is an event Handler for MOUSE_OUT event on all menus and its sub menus

 INPUT :

 IN_Event - MouseEvent

 ************************************************************************************************/

 private function outHandler(IN_Event:MouseEvent):void{

  IN_Event.target.MouseOver = false;
 
  stage.addEventListener(Event.ENTER_FRAME,hideMenu);
 


 }




 /***********************************************************************************************

 This function ceate for menu objects


 INPUT :

 int_Height - int

 int_width  - int

 num_color  - Number

 int_cornerRadius - int


 RETURN :

 mc_menu - MovieClip



 ************************************************************************************************/

 private function createMenuItem(int_Height:int,int_width:int,num_color:Number,int_cornerRadius:int):MovieClip{
 
  var mc_menu:MovieClip = new MovieClip();
 
  mc_menu.graphics.lineStyle(1,0X000000,1);
 
  mc_menu.graphics.beginFill(num_color,1);
 
  mc_menu.graphics.drawRoundRect(0,0,int_width,int_Height,int_cornerRadius,int_cornerRadius);
 
  mc_menu.graphics.endFill();
 
  var txt_menuItem:TextField = new TextField();
 
  txt_menuItem.height = int_Height;
 
  txt_menuItem.width = int_width;
 
  txt_menuItem.autoSize = TextFieldAutoSize.CENTER;
 
  txt_menuItem.selectable = false;
   mc_menu.addChild(txt_menuItem);
 
  mc_menu.mouseChildren = false;
 
  mc_menu.buttonMode = true;
 
  return mc_menu;
 }




 /***********************************************************************************************

 This function is an event Handler for ENTER_FRAME event on stage

 INPUT :

 IN_Event - Event

 ************************************************************************************************/

 private function hideMenu(IN_Event:Event):void{
 
  if(arr_menuItem.length >0){

   if(mc_currentMenu.MouseOver == false && !arr_menuItem.some(CheckMouseOver)){

    mc_menuHolder.getChildByName("mc_subMenu_"+unt_currentID).visible = false;

   }
  
  stage.removeEventListener(Event.ENTER_FRAME,hideMenu);
 
  }
 
 }




 /***********************************************************************************************

 This function checks for MOUSE_OVER event on every menus and menu items

 INPUT :

 arr - Array


 RETURN :

 A Boolean value


 ************************************************************************************************/

 private function CheckMouseOver(element:*, index:int, arr:Array):Boolean {

   return element.MouseOver;
  }



}
}

Simple Flash Analog Clock - AS3

2009-08-27T04:28:00.000-07:00

Download clock.zip, 11 KB (Flash CS3|CS4 professional)

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// ActionScript 3.0
// 28-August-2009
// http://flash-workshop.blogspot.com/
package {
 import flash.display.MovieClip;

import flash.events.Event;

import flash.text.TextField;

   import flash.text.TextFieldAutoSize;

   import flash.text.TextFormat;
 public class clock extends MovieClip {
  var mc_hourHand:MovieClip;
  var mc_minHand:MovieClip;
  var mc_secHand:MovieClip;
  var dte_currentDate:Date = new Date();
  var num_hour:Number;
 
  public function clock():void {
 
  numbers();
   this.graphics.lineStyle(15,0xFF9900);
   this.graphics.drawCircle(stage.stageWidth/2,stage.stageHeight/2,stage.stageWidth/2-10);
   mc_hourHand=drawLine(100,12);
   addChild(mc_hourHand);
   mc_hourHand.x=stage.stageWidth/2;
   mc_hourHand.y=stage.stageHeight/2;
 
   mc_minHand=drawLine(140,8);
   addChild(mc_minHand);
   mc_minHand.x=stage.stageWidth/2;
   mc_minHand.y=stage.stageHeight/2;
 
   mc_secHand=drawLine(170,5);
   addChild(mc_secHand);
   mc_secHand.x=stage.stageWidth/2;
   mc_secHand.y=stage.stageHeight/2;
   stage.addEventListener(Event.ENTER_FRAME,enterFrameHandler);
 
 
  this.graphics.beginFill(0xFF9900,1);
   this.graphics.drawCircle(stage.stageWidth/2,stage.stageHeight/2,15);
   this.graphics.endFill();
 
 
 
 }


 
  private function drawLine(Length:Number,thickness:Number):MovieClip {
   var mc_line:MovieClip = new MovieClip();
   mc_line.graphics.lineStyle(thickness,0xFF9900);
   mc_line.graphics.lineTo(0,Length-Length-Length);
   return mc_line;
  }
  private function enterFrameHandler(IN_Event:Event):void {
   dte_currentDate = new Date();
   num_hour=dte_currentDate.hours;
   if (num_hour>12) {
    num_hour-=12;
  }
   mc_hourHand.rotation=(num_hour+(dte_currentDate.minutes/60)+(dte_currentDate.seconds/3600))*30;
   mc_minHand.rotation=(dte_currentDate.minutes+(dte_currentDate.seconds/60))*6;
   mc_secHand.rotation=dte_currentDate.seconds*6;
  }

 private function numbers():void{
 
 
  var format:TextFormat = new TextFormat();
           format.font = "Verdana";
           format.color = 0xFF9900;
           format.size = 35;
  format.bold = true;
           
 
  var txt_TextField_12:TextField = new TextField();
 
  txt_TextField_12.selectable = false;
 
  txt_TextField_12.defaultTextFormat = format;
 
  txt_TextField_12.autoSize = TextFieldAutoSize.CENTER;
 
  txt_TextField_12.text = "12";
 
  addChild(txt_TextField_12);
 
  txt_TextField_12.x = stage.stageWidth/2 -txt_TextField_12.width/2 ;
 
  txt_TextField_12.y = 25;
 
 
  var txt_TextField_3:TextField = new TextField();
 
  txt_TextField_3.selectable = false;
 
  txt_TextField_3.defaultTextFormat = format;
 
  txt_TextField_3.autoSize = TextFieldAutoSize.CENTER;
 
  txt_TextField_3.text = "3";
 
  addChild(txt_TextField_3);
 
  txt_TextField_3.x = stage.stageWidth - 50;
 
  txt_TextField_3.y = stage.stageHeight/2 -txt_TextField_3.height/2;
 
 
 
  var txt_TextField_6:TextField = new TextField();
 
  txt_TextField_6.selectable = false;
 
  txt_TextField_6.defaultTextFormat = format;
 
  txt_TextField_6.autoSize = TextFieldAutoSize.CENTER;
 
  txt_TextField_6.text = "6";
 
  addChild(txt_TextField_6);
 
  txt_TextField_6.x =stage.stageWidth/2 -txt_TextField_6.width/2 ;
 
  txt_TextField_6.y =stage.stageHeight - 70 ;
 
 
 
  var txt_TextField_9:TextField = new TextField();
 
  txt_TextField_9.selectable = false;
 
  txt_TextField_9.defaultTextFormat = format;
 
  txt_TextField_9.autoSize = TextFieldAutoSize.CENTER;
 
  txt_TextField_9.text = "9";
 
  addChild(txt_TextField_9);
 
  txt_TextField_9.x =30;
 
  txt_TextField_9.y =stage.stageHeight/2 -txt_TextField_9.height/2 ;
 
  
  }


}
}

AS3 - Access objects from external SWF files

2009-04-30T07:15:00.000-07:00

Download accessExternalSwf.zip, 25 KB (Flash CS4 professional)

loadSWFs.as

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// ActionScript 3.0
// 30-April-2009
// http://flash-workshop.blogspot.com/
package {
 import flash.display.MovieClip;
 import flash.display.Shape;
 import flash.net.URLRequest;
 import flash.display.Loader;
 import flash.events.ProgressEvent;
 import flash.events.Event;
 import flash.text.TextField;
 import flash.text.TextFieldAutoSize;
 import flash.events.MouseEvent;
 public class loadSWFs extends MovieClip {
  var shp_mainLine:Shape;
  var shp_statusLine:Shape;
  var txt_status:TextField;
  var mc_loadedMovieClip:MovieClip = new MovieClip();
 
  public function loadSWFs():void {
   mc_access.buttonMode=true;
   mc_pass.buttonMode=true;
   mc_access.mouseChildren=false;
   mc_pass.mouseChildren=false;
   
   mc_load.mouseChildren=false;
   
   mc_load.buttonMode=true;
   
      
   mc_access.visible = false;
   
   mc_pass.visible = false;
   
   
   
   mc_load.addEventListener(MouseEvent.CLICK,loadSWF);
   mc_access.addEventListener(MouseEvent.CLICK,accessData);
   mc_pass.addEventListener(MouseEvent.CLICK,passData);
   addChild(mc_loadedMovieClip);
  }
  
  
  function loadSWF(IN_Event:MouseEvent):void {
   
   mc_load.visible = false;
   
   mc_access.visible = true;
   
   mc_pass.visible = true;
   
   
   
   
   createStatusBar();
   var loader:Loader=new Loader  ;
   loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS,progressHandler);
   loader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeHandler);
   loader.load(new URLRequest("swf/externalSWF.swf"));
   
   
   
  }
  function accessData(IN_Event:MouseEvent):void {
   var mc_object:MovieClip=MovieClip(mc_loadedMovieClip.getChildAt(0));
   txt_mainMovie.text=mc_object.txt_external.text;
  }
  function passData(IN_Event:MouseEvent):void {
   var mc_object:MovieClip=MovieClip(mc_loadedMovieClip.getChildAt(0));
   mc_object.txt_external.text = txt_mainMovie.text;
   
  }
  function completeHandler(IN_Event:Event):void {
   mc_loadedMovieClip.addChild(IN_Event.target.content);
   this.removeChild(shp_mainLine);
   this.removeChild(shp_statusLine);
   this.removeChild(txt_status);
  }
 
 
  function progressHandler(IN_Event:ProgressEvent):void {
   var percent:Number=IN_Event.bytesLoaded*100/IN_Event.bytesTotal;
   shp_statusLine.scaleX=percent/100;
   txt_status.text=Math.round(percent)+" %";
  }
  function createStatusBar():void {
   shp_mainLine=new Shape  ;
   shp_mainLine.graphics.lineStyle(8,0x00CC00);
   shp_mainLine.graphics.lineTo(200,0);
   shp_mainLine.x=stage.stageWidth/2-shp_mainLine.width/2;
   shp_mainLine.y=stage.stageHeight/2;
   shp_statusLine=new Shape  ;
   shp_statusLine.graphics.lineStyle(1,0xFFFFFF);
   shp_statusLine.graphics.lineTo(200,0);
   shp_statusLine.scaleX=.01;
   shp_statusLine.x=stage.stageWidth/2-shp_mainLine.width/2;
   shp_statusLine.y=stage.stageHeight/2;
   txt_status=new TextField  ;
   txt_status.autoSize=TextFieldAutoSize.CENTER;
   txt_status.selectable=false;
   txt_status.textColor=0x000000;
   txt_status.y=shp_mainLine.y+10;
   txt_status.x=shp_mainLine.x+shp_mainLine.width/2;
   this.addChild(shp_mainLine);
   this.addChild(shp_statusLine);
   this.addChild(txt_status);
 
  }
 }
}

externalSWF.as

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// ActionScript 3.0
// 30-April-2009
// http://flash-workshop.blogspot.com/
package {
 import flash.display.MovieClip;
 
 import flash.events.MouseEvent;
 public class externalSWF extends MovieClip {
  public function externalSWF():void {
   mc_access.buttonMode=true;
   mc_pass.buttonMode=true;
   mc_access.mouseChildren=false;
   mc_pass.mouseChildren=false;
   mc_access.addEventListener(MouseEvent.CLICK,accessData);
   mc_pass.addEventListener(MouseEvent.CLICK,passData);
  }
  function accessData(IN_Event:MouseEvent):void {
   var tempObject=this.parent.parent;
   this.txt_external.text=tempObject.txt_mainMovie.text;
  }
  function passData(IN_Event:MouseEvent):void {
   var tempObject=this.parent.parent;
   tempObject.txt_mainMovie.text=this.txt_external.text;
  }
 }
}

Flash CS3 - XML - Photo Viewer

2009-04-29T03:25:00.000-07:00

Download PhotoViewer.zip, 588 KB

PhotoViewer.as

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// ActionScript 3.0
// 29-April-2009
// http://flash-workshop.blogspot.com/
package {
 import flash.display.MovieClip;
 import flash.display.Shape;
 import flash.display.Loader;
 import flash.utils.Timer;
 import flash.events.TimerEvent;
 import flash.events.Event;
 import flash.events.ProgressEvent;
 import fl.transitions.*;
 import fl.transitions.easing.*;
 import flash.net.URLRequest;
 import flash.text.TextField;
 import flash.text.TextFieldAutoSize;
 import flash.net.URLLoader;
 public class PhotoViewer extends MovieClip {
  var mc_mask:MovieClip = new MovieClip();
  var photoTimer:Timer=new Timer(3000);
  var i:uint=0;
  var uint_rndUInt:uint=0;
  var arr_type:Array=new Array(Blinds,Fade,Fly,Iris,Photo,PixelDissolve,Rotate,Squeeze,Wipe,Zoom);
  var arr_imagesURLs:Array = new Array();
  var arr_images:Array = new Array();
  var shp_mainLine:Shape;
  var shp_statusLine:Shape;
  var txt_status:TextField;
  var txt_fileStatus:TextField;
  var xmlData:XML= new XML();
  var xmlLoader:URLLoader = new URLLoader();
  public function PhotoViewer():void {
   stage.frameRate=30;
   photoTimer.addEventListener("timer", timerHandler);
   xmlLoader=new URLLoader(new URLRequest("images.xml"));
   xmlLoader.addEventListener(Event.COMPLETE,gotXML);
 
  }
  function gotXML(evt:Event):void {
   xmlLoader.removeEventListener(Event.COMPLETE,gotXML);
   xmlData=XML(xmlLoader.data);
   for each (var item:XML in xmlData..image) {
    arr_imagesURLs.push(item);
   }
   createStatusBar();
   loadImages();
  }
  function loadImages():void {
   txt_fileStatus.text="Loading \""+arr_imagesURLs[i]+"\"";
   var loader:Loader = new Loader();
   loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);
   loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
   loader.load(new URLRequest("images/"+arr_imagesURLs[i++]));
  }
  function progressHandler(IN_Event:ProgressEvent):void {
   var percent:Number=IN_Event.bytesLoaded*100/IN_Event.bytesTotal;
   shp_statusLine.scaleX=percent/100;
   txt_status.text=Math.round(percent)+" %";
  }
  function completeHandler(IN_Event:Event):void {
   var mc_image:MovieClip = new MovieClip();
   IN_Event.target.content.x=- IN_Event.target.content.width/2;
   IN_Event.target.content.y=- IN_Event.target.content.height/2;
   mc_image.addChild(IN_Event.target.content);
   mc_image.visible=false;
   addChild(mc_image);
   arr_images.push(mc_image);
   if (i<arr_imagesURLs.length) {
    loadImages();
   } else {
    removeChild(shp_mainLine);
    removeChild(shp_statusLine);
    removeChild(txt_status);
    removeChild(txt_fileStatus);
    uint_rndUInt=randomInRange(0,arr_images.length-1);
    arr_images[uint_rndUInt].x=arr_images[uint_rndUInt].width/2;
    arr_images[uint_rndUInt].y=arr_images[uint_rndUInt].height/2;
    TransitionManager.start(arr_images[uint_rndUInt], {type:arr_type[randomInRange(0,arr_type.length-1)], direction:Transition.IN, duration:1, easing:None.easeNone});
    photoTimer.start();
   }
  }
  public function timerHandler(event:TimerEvent):void {
   while (uint_rndUInt == (uint_rndUInt=randomInRange(0,arr_images.length-1))) {
   }
   arr_images[uint_rndUInt].x=arr_images[uint_rndUInt].width/2;
   arr_images[uint_rndUInt].y=arr_images[uint_rndUInt].height/2;
   this.setChildIndex(arr_images[uint_rndUInt],this.numChildren-1);
   TransitionManager.start(arr_images[uint_rndUInt], {type:arr_type[randomInRange(0,arr_type.length-1)], direction:Transition.IN, duration:1, easing:None.easeNone});
  }
 
 
  /**************************************************************************************************
    
    This function returns a random number between min and max number
    
    **************************************************************************************************/
  function randomInRange(min:Number,max:Number):Number {
   var scale:Number=max- (--min);
   return Math.ceil(Math.random() * scale + min);
  }
 
  function createStatusBar():void {
   shp_mainLine = new Shape();
   shp_mainLine.graphics.lineStyle(8,0x00CC00);
   shp_mainLine.graphics.lineTo(200,0);
   shp_mainLine.x = (stage.stageWidth/2)-(shp_mainLine.width/2);
   shp_mainLine.y = (stage.stageHeight/2);
   shp_statusLine = new Shape();
   shp_statusLine.graphics.lineStyle(1,0xFFFFFF);
   shp_statusLine.graphics.lineTo(200,0);
   shp_statusLine.scaleX=.01;
   shp_statusLine.x=(stage.stageWidth/2)-(shp_mainLine.width/2);
   shp_statusLine.y=(stage.stageHeight/2);
   txt_status = new TextField();
   txt_status.autoSize=TextFieldAutoSize.CENTER;
   txt_status.selectable=false;
   txt_status.textColor=0x000000;
   txt_status.y=shp_mainLine.y+10;
   txt_status.x=shp_mainLine.x + (shp_mainLine.width/2);
 
   txt_fileStatus = new TextField();
   txt_fileStatus.autoSize=TextFieldAutoSize.CENTER;
   txt_fileStatus.selectable=false;
   txt_fileStatus.textColor=0x000000;
   txt_fileStatus.y=shp_mainLine.y-30;
   txt_fileStatus.x=shp_mainLine.x + (shp_mainLine.width/2);
   addChild(shp_mainLine);
   addChild(shp_statusLine);
   addChild(txt_status);
   addChild(txt_fileStatus);
  }
 }
}

Flash CS3 | CS4 - Mouse Trail

2009-04-26T22:35:00.000-07:00

Download MouseTrail.zip, 11 KB

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// ActionScript 3.0
// 27-April-2009
// http://flash-workshop.blogspot.com/
package {
 import flash.display.MovieClip;
 import flash.events.Event;
 import flash.display.StageAlign;
 import flash.display.StageScaleMode;
 public class MouseTrail extends MovieClip {
 
  /**************************************************************************************************
  
  Default constructor
  
  **************************************************************************************************/
  public function MouseTrail():void {
   var uint_NumberOfParticles:uint=30;
   stage.frameRate=30;
   stage.scaleMode=StageScaleMode.NO_SCALE;
   for (var i:uint=0; i<uint_NumberOfParticles; i++) {
    var mc_particle:MovieClip=createParticle(((uint_NumberOfParticles-i)/5)+.8);
    mc_particle.alpha= 1-(i /  uint_NumberOfParticles);
    mc_particle.id=i;
    mc_particle.addEventListener(Event.ENTER_FRAME,moveparticles);
    addChild(mc_particle);
   }
  }
 
  /**************************************************************************************************
  
  This function is an event handler for mouse click on nextBtn
  
  
  INPUT:
  
  IN_event - Event
  
  
  **************************************************************************************************/
  function moveparticles(IN_Event:Event):void {
   IN_Event.target.x += (mouseX-IN_Event.target.x)/IN_Event.target.id;
   IN_Event.target.y += (mouseY-IN_Event.target.y)/IN_Event.target.id;
  }
 
  /**************************************************************************************************
  
  This function is an event handler for mouse click on nextBtn
  
  
  INPUT:
  
  num_radius - Number
  
  
  OUTPUT:
  
  mc_particle - MovieClip
  
  **************************************************************************************************/
  function createParticle(num_radius:Number):MovieClip {
   var mc_particle:MovieClip=new MovieClip  ;
   mc_particle.graphics.beginFill(0xFF9900,1);
   mc_particle.graphics.drawCircle(0,0,num_radius);
   mc_particle.graphics.endFill();
   return mc_particle;
  }
 }//End of class
}//End of package

Flash CS3 - 360 Degree View

2009-03-31T22:56:00.000-07:00

Move your mouse over the image

Download ThreeSixtyCS3.zip (134 KB)

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// ActionScript 3.0
// 01-April-2009
// http://flash-workshop.blogspot.com/
package {
 import flash.display.*;
 import flash.events.*;
 import flash.net.*;
 import flash.geom.*;
 import flash.text.TextField;
 import flash.text.TextFieldAutoSize;
 import flash.filters.DropShadowFilter;
 public class ThreeSixty extends MovieClip {
  var camera:Bitmap;
  var textureMap:BitmapData;
  var Height:int;
  var Width:int;
  var sourceX:int=0;
  var shp_mainLine:Shape;
  var shp_statusLine:Shape;
  var txt_status:TextField;
  var speed:Number;
 
  var mc_rightButton:MovieClip;
  var mc_leftButton:MovieClip;
  public function ThreeSixty():void {
   stage.frameRate=30;
   var imageLoader:Loader=new Loader();
   createStatusBar();
   imageLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);
   imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,imageLoadComplete);
   imageLoader.load(new URLRequest("landscape.jpg"));
  }
  private function imageLoadComplete(IN_Event:Event):void {
 
   removeChild(shp_mainLine);
   removeChild(shp_statusLine);
   removeChild(txt_status);
   textureMap=IN_Event.target.content.bitmapData;
   Height=textureMap.height;
   Width=textureMap.width;
   camera=new Bitmap  ;
   camera.bitmapData=new BitmapData(550,384);
   addChild(camera);
   stage.addEventListener(MouseEvent.MOUSE_MOVE,mouseMoveFunction);
   stage.addEventListener(Event.ENTER_FRAME,moveCameraFunction);
 
   mc_rightButton=createArrowKey();
   mc_leftButton=createArrowKey();
   mc_rightButton.rotation=180;
   mc_rightButton.x=550;
   mc_rightButton.scaleX=.5;
   mc_rightButton.scaleY=.5;
   mc_leftButton.scaleX=.5;
   mc_leftButton.scaleY=.5;
   addChild(mc_rightButton);
   addChild(mc_leftButton);
  }
  function progressHandler(IN_Event:ProgressEvent):void {
   var percent:Number=IN_Event.bytesLoaded*100/IN_Event.bytesTotal;
   shp_statusLine.scaleX=percent/100;
   txt_status.text=Math.round(percent)+" %";
  }
  function createStatusBar():void {
   shp_mainLine = new Shape();
   shp_mainLine.graphics.lineStyle(8,0x00CC00);
   shp_mainLine.graphics.lineTo(200,0);
   shp_mainLine.x = (stage.stageWidth/2)-(shp_mainLine.width/2);
   shp_mainLine.y = (stage.stageHeight/2);
   shp_statusLine = new Shape();
   shp_statusLine.graphics.lineStyle(1,0xFFFFFF);
   shp_statusLine.graphics.lineTo(200,0);
   shp_statusLine.scaleX=.01;
   shp_statusLine.x=(stage.stageWidth/2)-(shp_mainLine.width/2);
   shp_statusLine.y=(stage.stageHeight/2);
   txt_status = new TextField();
   txt_status.autoSize=TextFieldAutoSize.CENTER;
   txt_status.selectable=false;
   txt_status.textColor=0x000000;
   txt_status.y=shp_mainLine.y+10;
   txt_status.x=shp_mainLine.x + (shp_mainLine.width/2);
   addChild(shp_mainLine);
   addChild(shp_statusLine);
   addChild(txt_status);
  }
 
  function mouseMoveFunction(IN_Event:MouseEvent):void {
   speed = (mouseX-(stage.stageWidth/2))/10;
  }
  function moveCameraFunction(IN_Event:Event):void {
   sourceX += (speed);
   if (speed<0&&sourceX<=0) {
    sourceX=textureMap.width-550;
   } else if (speed>0&&sourceX>=textureMap.width-550) {
    sourceX=0;
   }
   camera.bitmapData.copyPixels(textureMap,new Rectangle(sourceX,0,camera.width,camera.height),new Point(0,0));
  }
  private function createArrowKey():MovieClip {
   var ArrowKey=new MovieClip  ;
   ArrowKey.graphics.beginFill(0x6532FF,1);
   ArrowKey.graphics.lineStyle(1,0x000000);
   ArrowKey.graphics.lineTo(60,-50);
   ArrowKey.graphics.lineTo(45,-5);
   ArrowKey.graphics.lineTo(100,-30);
   ArrowKey.graphics.lineTo(100,30);
   ArrowKey.graphics.lineTo(45,15);
   ArrowKey.graphics.lineTo(50,50);
   ArrowKey.graphics.lineTo(0,0);
   ArrowKey.y=300;
   ArrowKey.buttonMode=true;
   ArrowKey.filters=[new DropShadowFilter(5,10,0X000000,1,7,7,1,1)];
   return (ArrowKey);
  }
 }
}

Flash CS3 - Snowfall

2009-03-03T22:07:00.000-08:00

Download flashSnowCS3.zip (7 KB)

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// http://flash-workshop.blogspot.com/
// ActionScript 3.0
package {
 import flash.display.MovieClip;
 import flash.events.Event;
 import flash.filters.BlurFilter;
 public class flashSnow extends MovieClip {
  public function flashSnow():void {
   stage.frameRate=30;
   stage.addEventListener(Event.ENTER_FRAME,createSnow);
  }
  function createSnow(IN_Event:Event):void {
   if (randomInRange(1,3)==1) {
    var mc_particle:MovieClip=createCircle(randomInRange(3,10));
    mc_particle.x=randomInRange(0,stage.stageWidth);
    mc_particle.id=randomInRange(0,2);
    mc_particle.filters=[new BlurFilter(10,10,2)];
    mc_particle.addEventListener(Event.ENTER_FRAME,moveSnow);
    addChild(mc_particle);
   }
  }
  function createCircle(radius:Number):MovieClip {
   var mc_circle:MovieClip =new MovieClip();
   
   mc_circle.graphics.beginFill(0xFFFFFF,1);
   
   mc_circle.graphics.drawCircle(0,0,radius);
   
   mc_circle.graphics.endFill();
   
   return (mc_circle);
  }
  function moveSnow(IN_Event:Event):void {
   if (IN_Event.target.y>stage.stageHeight) {
    IN_Event.target.removeEventListener(Event.ENTER_FRAME,moveSnow);
    removeChild(MovieClip(IN_Event.target));
   }
   IN_Event.target.y += (IN_Event.target.width)/10;
   if (IN_Event.target.id==0) {
    IN_Event.target.x += (IN_Event.target.width)/30;
   } else if (IN_Event.target.id==1) {
    IN_Event.target.x -= (IN_Event.target.width)/30;
   }
  }
  /**************************************************************************************************
  
  This function return a random number between min and max number
  
  **************************************************************************************************/
  function randomInRange(min:Number,max:Number):Number {
   var scale:Number=max- (--min);
   return Math.ceil(Math.random() * scale + min);
  }
 }
}

Flash CS4 - 3D Rotating Menu

2009-02-23T21:22:00.000-08:00

Download RotatingMenu.zip (8 KB)

ActionScript Code:

// Developed by Anil kumar N D
// anilkumarnd@gmail.com
// http://flash-workshop.blogspot.com/
// ActionScript 3.0
package {
 import flash.display.MovieClip;
 import flash.events.*;
 import flash.text.TextField;
 import flash.text.TextFormat;
 import flash.text.TextFormatAlign;
 import flash.filters.BitmapFilter;
 import flash.filters.BitmapFilterQuality;
 import flash.filters.BlurFilter;
 import flash.filters.DropShadowFilter;
 public class RotatingMenu extends MovieClip {
  var RectNo:Number=10;
  var i:Number;
  var rectangle:MovieClip;
  var radius:Number;
  var speed:Number=0;
  var xcenter:Number;
  var ycenter:Number;
  var degree:Number;
  var radian:Number=0;
  var MovieClipArray:Array=new Array  ;
  var rectContainer:MovieClip=new MovieClip  ;
  var newFormat:TextFormat = new TextFormat();
  public function RotatingMenu():void {
   stage.frameRate=30;
   CreateRectz();
  }
  function CreateRectz():void {
   addChild(rectContainer);
   for (i=0; i<RectNo; i++) {
    rectangle=CreateRect(0x000000,70,45);
    var txt_menu:TextField = new TextField();
    txt_menu.text="Menu "+i;
    txt_menu.selectable=false;
    txt_menu.mouseEnabled=false;
    txt_menu.width=60;
    txt_menu.height=20;
    txt_menu.x=-30;
    txt_menu.y=-10;
    newFormat.size=15;
    newFormat.bold=true;
    newFormat.color=0xFFFFFF;
    newFormat.align=TextFormatAlign.LEFT;
    txt_menu.setTextFormat(newFormat);
    
    rectangle.addChild(txt_menu);
    rectangle.radius=125;
    rectangle.speed=speed;
    rectangle.degree=i*360/RectNo;
    rectangle.radian=rectangle.degree/180*Math.PI;
    rectangle.x=+ Math.cos(rectangle.radian)*rectangle.radius;
    rectangle.y=- Math.sin(rectangle.radian)*rectangle.radius/5;
    rectangle.mouseChildren=false;
    MovieClipArray[i]=rectangle;
    rectContainer.buttonMode=true;
    rectContainer.addChild(rectangle);
    rectangle.addEventListener(Event.ENTER_FRAME,RotateFunction);
    rectangle.addEventListener(MouseEvent.MOUSE_OVER,OverFunction);
    rectangle.addEventListener(MouseEvent.MOUSE_OUT,OutFunction);
   }
   rectContainer.x=stage.stageWidth/2;
   rectContainer.y=stage.stageHeight/2;
   stage.addEventListener(MouseEvent.MOUSE_MOVE,mouseMoveFunction);
  }
  function mouseMoveFunction(e:Event):void {
   speed = (mouseX-(stage.stageWidth/2))/100;
  }
  function RotateFunction(e:Event):void {
   MovieClip(e.target).scaleX =((((Number(MovieClip(e.target).y)+50)*30)/100)+70)/100;
   MovieClip(e.target).scaleY = ((((Number(MovieClip(e.target).y)+50)*30)/100)+70)/100;
  
   var NumBlur:Number = -Number(MovieClip(e.target).y-30);
   
   NumBlur = NumBlur/5;
   MovieClip(e.target).filters=[(new BlurFilter(NumBlur,NumBlur,BitmapFilterQuality.HIGH))];
   
   if (MovieClip(e.target).x>14&&MovieClip(e.target).y<250) {
    rectContainer.setChildIndex(MovieClip(e.target),0);
   }
   if (MovieClip(e.target).y>14&&MovieClip(e.target).x<250) {
    rectContainer.setChildIndex(MovieClip(e.target),MovieClipArray.length - 1);
   }
 
   e.target.degree+=speed;
   e.target.radian=e.target.degree/180*Math.PI;
   e.target.x=+ Math.cos(e.target.radian)*e.target.radius;
   e.target.y=- Math.sin(e.target.radian)*e.target.radius/5;
 
  }
  function OverFunction(e:MouseEvent):void {
   for (i=0; i<RectNo; i++) {
    MovieClipArray[i].removeEventListener(Event.ENTER_FRAME,RotateFunction);
   }
  }
  function OutFunction(e:MouseEvent):void {
   for (i=0; i<RectNo; i++) {
    MovieClipArray[i].addEventListener(Event.ENTER_FRAME,RotateFunction);
   }
  }
  private function CreateRect(color:Number,Width:Number,Height:Number):MovieClip {
   var Rect:MovieClip=new MovieClip  ;
   Rect.graphics.beginFill(color,.7);
   Rect.graphics.drawRect(0-Width/2,0-Height/2,Width,Height);
   Rect.graphics.endFill();
   return Rect;
  }
 }
}

Flash CS3 - Butterflies (Testing)

2009-02-04T03:53:00.000-08:00

Flash CS3 - Flash particle effect

2009-02-03T05:00:00.000-08:00

Download FlashParticlesCS3.zip (6 KB)

ActionScript Code:

import fl.transitions.Tween;
import fl.transitions.easing.*;
stage.frameRate=30;
var radius:Number=100;
var speed:Number=1;
var degree:Number=0;
 
stage.addEventListener(MouseEvent.MOUSE_MOVE,createPartcles);
function createPartcles(IN_Event:MouseEvent):void {
 var particle:MovieClip = new mc_cirlce();
 particle.x=mouseX;
 particle.y=mouseY;
 addChild(particle);
 particleTween(particle);
 particle.addEventListener(Event.ENTER_FRAME,removeParticle);
}
 
function particleTween(particle:MovieClip):void {
 degree+=speed;
 var myTween:Tween=new Tween(particle,"x",Regular.easeOut,particle.x,particle.x+Math.cos(degree)*radius,2,true);
 var myTween2:Tween=new Tween(particle,"y",Regular.easeOut,particle.y,particle.y+Math.sin(degree)*radius,2,true);
 var myTween3:Tween=new Tween(particle,"alpha",Regular.easeOut,1,0,2,true);
}
function removeParticle(IN_Event:Event):void {
 MovieClip(IN_Event.target).filters=[new BlurFilter(Math.abs(IN_Event.target.width),Math.abs(IN_Event.target.width),1)];
 MovieClip(IN_Event.target).width+=.3;
 MovieClip(IN_Event.target).height+=.3;
 if (IN_Event.target.alpha==0||IN_Event.target.width>30) {
  IN_Event.target.removeEventListener(Event.ENTER_FRAME,removeParticle);
  removeChild(MovieClip(IN_Event.target));
 }
}

Flash CS3 - Circular Motion - Rotating Square

2008-10-30T02:22:00.000-07:00

ActionScript Code:

stage.frameRate=30;
//draw square
var square:Shape = new Shape();
square.graphics.beginFill(0xFF6600,1);
square.graphics.drawRect(-25,-25,50,50);
square.graphics.endFill();
square.x=stage.stageWidth/2;
square.y=stage.stageHeight/2;
addChild(square);
//draw circle
var circle:Shape = new Shape();
circle.graphics.lineStyle(1,0x00FFCC);
circle.graphics.drawCircle(0,0,100);
circle.x=stage.stageWidth/2;
circle.y=stage.stageHeight/2;
addChild(circle);
//Animate SquaRE
var radius:Number = 100;
var speed:Number = .1;
var xcenter:Number = square.x;
var ycenter:Number = square.y;
var degree:Number = 0;
stage.addEventListener(Event.ENTER_FRAME,myFunction);
function myFunction(e:Event):void {
 degree += speed;
 square.x = xcenter+Math.cos(degree)*radius;
 square.y = ycenter+Math.sin(degree)*radius;
}

Flash CS3 - Flash Random Quiz with Timer (AS3)

2008-10-29T00:11:00.000-07:00

Download FlashQuiz.zip (12 KB)

ActionScript Code:

package {
 import flash.display.MovieClip;
 import flash.display.Shape;
 import flash.text.TextField;
 import flash.text.TextFieldAutoSize;
 import flash.text.TextFormat;
 import flash.text.TextFormatAlign;
 import flash.text.AntiAliasType;
 import flash.utils.Timer;
 import flash.events.TimerEvent;
 import flash.events.MouseEvent;
 public class FlashQuiz extends MovieClip {
  var Circle=new Shape;
  var Line=new Shape;
  var time:Number=10;//edit it to change time limit duration 
  var counter:Number=0;
  var rotator:Number=0;
  var myTimer:Timer=new Timer(1000);
  var newFormat:TextFormat=new TextFormat;
  var QuestionTextField=new TextField;
  var QuestionTextField2=new TextField;
  var questions:Array=new Array;
  var answers:Array=new Array;
  var questionsLength:Number;
  var questionsLengthCheck:Number=1;
  var arr_randumNumbers:Array=new Array;
  var arr_randumNumbers2:Array=new Array;
  var m_iIndex:uint;
  var Text;
  var Qno:Number=1;
  var StartButton=CreateRect(0xCCCCCC,100,20);
  var answer1=CreateRect(0xCCCCCC,100,20);
  var answer2=CreateRect(0xCCCCCC,100,20);
  var answer3=CreateRect(0xCCCCCC,100,20);
  var answer4=CreateRect(0xCCCCCC,100,20);
  var ResultField=CreateRect(0xFFFFC4,300,50);
  var correctAnswer:String;
  var score:uint=0;
  var scoreTextField=new TextField;
  public function FlashQuiz():void {
   questions[0]="What is the most common Element on Earth?";
   questions[1]="How Long Does it take for light from the moon to reach the Earth?";
   questions[2]="How many miles high is Mount Everest?";
   questions[3]="Which Ocean goes to the deepest depths?";
   questions[4]="What is the Currency in Chili ? ";
   questions[5]="What is 4ft 8inches in Metres ?";
   questions[6]="How many members were originally in the group Spice Girls ?";
   questions[7]="If I take 2 apples out of a basket containing 6 apples how many apples do I have ?";
   questions[8]="What is your birth sign If you were born November 25th ?";
   questions[9]="What year did the Vietnam war end?";
   answers=[["Hydrogen","Oxygen","Human beings","Soil"],["1.26 Secs","1.62 Secs","6.21 Secs","2.16 Secs"],["8.846","8.864","8.486","8.648"],["Pacific Ocean","Atlantic Ocean","Indian Ocean","Southern Ocean"],["Peso","Abasi","Cedi","Denar"],["1.42 Metres","1.24 Metres","4.12 Metres","2.41 Metres"],["5","6","7","8"],["2","6","4","3"],["Sagittarius","Capricorn","Pisces","Libra"],["1975","1979","1875","2008"]];
   questionsLength=questions.length;
   shuffleArray();
   shuffleArray2();
   DrawTimer();
   myTimer.addEventListener("timer",timerHandler);
   newFormat.size=20;
   newFormat.bold=true;
   newFormat.color=0x000000;
   newFormat.align=TextFormatAlign.LEFT;
   newFormat.font="Verdana";
   QuestionTextField.text="Click on start button";
   QuestionTextField.width=250;
   QuestionTextField.selectable=false;
   QuestionTextField.setTextFormat(newFormat);
   QuestionTextField.x=165;
   QuestionTextField.y=50;
   addChild(QuestionTextField);
   QuestionTextField2.width=200;
   QuestionTextField2.height=400;
   QuestionTextField2.multiline=true;
   QuestionTextField2.wordWrap=true;
   QuestionTextField2.selectable=false;
   QuestionTextField2.x=165;
   QuestionTextField2.y=75;
   addChild(QuestionTextField2);
   ResultField.width=200;
   ResultField.selectable=false;
   ResultField.x=0;
   ResultField.y=350;
   addChild(ResultField);
   Text=StartButton.getChildAt(0);
   Text.text="Start";
   StartButton.y=380;
   StartButton.x=300;
   StartButton.buttonMode=true;
   addChild(StartButton);
   StartButton.addEventListener(MouseEvent.CLICK,StartButtonCLICK);
   Text=answer1.getChildAt(0);
   Text.text="answers1";
   answer1.y=300;
   answer1.x=0;
   answer1.buttonMode=true;
   addChild(answer1);
   Text=answer2.getChildAt(0);
   Text.text="answers2";
   answer2.y=300;
   answer2.x=answer1.x + answer1.width + 5;
   answer2.buttonMode=true;
   addChild(answer2);
   Text=answer3.getChildAt(0);
   Text.text="answers3";
   answer3.y=300;
   answer3.x=answer2.x + answer2.width + 5;
   answer3.buttonMode=true;
   addChild(answer3);
   Text=answer4.getChildAt(0);
   Text.text="answers4";
   answer4.y=300;
   answer4.x=answer3.x + answer3.width + 5;
   answer4.buttonMode=true;
   addChild(answer4);
   answer1.visible=false;
   answer2.visible=false;
   answer3.visible=false;
   answer4.visible=false;
   answer1.addEventListener(MouseEvent.CLICK,answerCLICK);
   answer2.addEventListener(MouseEvent.CLICK,answerCLICK);
   answer3.addEventListener(MouseEvent.CLICK,answerCLICK);
   answer4.addEventListener(MouseEvent.CLICK,answerCLICK);
   addChild(ResultField);
   addChild(scoreTextField);
  }
  public function answerCLICK(e:MouseEvent):void {
   Text=e.target.getChildAt(0);
   if (Text.text == correctAnswer) {
    Text=ResultField.getChildAt(0);
    Text.text="Right";
    Text.setTextFormat(newFormat);
    score++;
   } else {
    Text=ResultField.getChildAt(0);
    Text.text="Wrong";
    Text.setTextFormat(newFormat);
   }
   nextQuestion();
  }
  public function StartButtonCLICK(e:MouseEvent):void {
   Text=ResultField.getChildAt(0);
   Text.text="";
   nextQuestion();
  }
 
  function nextQuestion():void {
   Text=StartButton.getChildAt(0);
   if (Text.text == "PlayAgain") {
    Qno=1;
    score=0;
    Text=ResultField.getChildAt(0);
    Text.text="";
   }
   if (Qno <= questionsLength) {
    answer1.visible=true;
    answer2.visible=true;
    answer3.visible=true;
    answer4.visible=true;
    myTimer.stop();
    myTimer.start();
    Line.rotation=0;
    rotator=0;
    counter=0;
    QuestionTextField.text="Question " + Qno;
    QuestionTextField.setTextFormat(newFormat);
    Text=StartButton.getChildAt(0);
    Text.text="Next";
    Text=answer1.getChildAt(0);
    correctAnswer=answers[arr_randumNumbers[Qno - 1]][0];
    Text.text=answers[arr_randumNumbers[Qno - 1]][arr_randumNumbers2[0]];
    Text=answer2.getChildAt(0);
    Text.text=answers[arr_randumNumbers[Qno - 1]][arr_randumNumbers2[1]];
    Text=answer3.getChildAt(0);
    Text.text=answers[arr_randumNumbers[Qno - 1]][arr_randumNumbers2[2]];
    Text=answer4.getChildAt(0);
    Text.text=answers[arr_randumNumbers[Qno - 1]][arr_randumNumbers2[3]];
    shuffleArray2();
    QuestionTextField2.text=questions[arr_randumNumbers[Qno++ - 1]];
   } else {
    Qno++;
    myTimer.stop();
    QuestionTextField.text="Completed";
    QuestionTextField.setTextFormat(newFormat);
    QuestionTextField2.text="";
    Text=StartButton.getChildAt(0);
    Text.text="PlayAgain";
    Line.rotation=0;
    rotator=0;
    answer1.visible=false;
    answer2.visible=false;
    answer3.visible=false;
    answer4.visible=false;
   }
   scoreTextField.text="Score " + String(score) + " / " + String(Qno - 2);
  }
  public function timerHandler(event:TimerEvent):void {
   rotator=rotator + 360 / time;
   Line.rotation=- rotator;
   counter++;
   if (counter==time) {
    counter=0;
    nextQuestion();
    Text=ResultField.getChildAt(0);
    Text.text="";
   }
  }
  public function DrawTimer():void {
   Circle.graphics.lineStyle(5,0x00FF00);
   Circle.graphics.drawCircle(100,100,50);
   Line.graphics.lineStyle(5,0x00FF00);
   Line.graphics.lineTo(0,-40);
   Line.x=100;
   Line.y=100;
   addChild(Circle);
   addChild(Line);
  }
  private function randomInRange(min:Number,max:Number):Number {
   var scale:Number=max - --min;
   return Math.ceil(Math.random() * scale + min);
  }
  function shuffleArray():void {
   var RanNumber:Number;
   arr_randumNumbers.splice(0,arr_randumNumbers.length);
   for (m_iIndex=0; m_iIndex < questionsLength; m_iIndex++) {
    while (arr_randumNumbers.indexOf(RanNumber=randomInRange(0,questionsLength - 1)) != -1) {
    }
    arr_randumNumbers.push(RanNumber);
   }
  }
  function shuffleArray2():void {
   var RanNumber:Number;
   arr_randumNumbers2.splice(0,arr_randumNumbers.length);
   for (m_iIndex=0; m_iIndex < 4; m_iIndex++) {
    while (arr_randumNumbers2.indexOf(RanNumber=randomInRange(0,3)) != -1) {
    }
    arr_randumNumbers2.push(RanNumber);
   }
  }
  private function CreateRect(color:Number,Width:Number,Height:Number):MovieClip {
   var Rect:MovieClip=new MovieClip;
   Rect.graphics.beginFill(color,1);
   Rect.graphics.drawRect(0,0,Width,Height);
   Rect.graphics.endFill();
   var textInBox=new TextField;
   textInBox.width=Width;
   textInBox.height=Height;
   Rect.addChild(textInBox);
   Rect.mouseChildren=false;
   textInBox.selectable=false;
   return Rect;
  }
 }
}

Magic Squares (Testing)

2008-10-10T05:56:00.001-07:00

Flash CS3 - XML Guestbook (AS3)

2008-09-30T07:23:00.000-07:00

view guestbook.xml

Download - XmlCs3GuestBook.zip

XmlCs3GuestBook.as

ActionScript Code:

package {
 import flash.display.MovieClip;
 import flash.display.Loader;
 import flash.net.URLLoader;
 import flash.net.URLRequest;
 import flash.events.*;
 import flash.text.TextField;
 import flash.text.TextFieldType;
 import fl.controls.ScrollBar;
 import fl.controls.UIScrollBar;
 import flash.text.TextFieldAutoSize;
 import fl.transitions.Tween;
 import fl.transitions.TweenEvent;
 import fl.transitions.easing.*;
 import flash.net.navigateToURL;
 import flash.net.URLRequest;
 import flash.net.URLVariables;
 import flash.net.URLRequestMethod;
 
 public class XmlCs3GuestBook extends MovieClip {
  var loader:Loader = new Loader();
  var xmlData:XML= new XML();
  var xmlLoader:URLLoader = new URLLoader();
  var TxtMessges:TextField = new TextField();
  var myScrollBar = new UIScrollBar();
  var MSGCounter:int = 1;
  var form = new MovieClip();
  public function XmlCs3GuestBook():void {
   stage.frameRate=30;
   xmlLoader = new URLLoader( new URLRequest("guestbook.xml") );
   xmlLoader.addEventListener(Event.COMPLETE, gotXML);
  }
  function gotXML(evt:Event):void {
   xmlData = XML(xmlLoader.data);
   for each (var item:XML in xmlData..Guest) {
    TxtMessges.appendText("Message "+MSGCounter++ +"\n");
    TxtMessges.appendText("Name - ");
    TxtMessges.appendText(item.name.toString());
    TxtMessges.appendText("\nEmail - ");
    TxtMessges.appendText(item.email.toString());
    TxtMessges.appendText("\nMessage - ");
    TxtMessges.appendText(item.message.toString());
    TxtMessges.appendText("\nTime - ");
    TxtMessges.appendText(item.time.toString());
    TxtMessges.appendText("\n------------------------------------------------------------------------\n");
    TxtMessges.appendText("\n\n");
   }
   TxtMessges.y=40;
   TxtMessges.width =380;
   TxtMessges.height=300;
   TxtMessges.border = true;
   TxtMessges.mouseWheelEnabled = true;
   TxtMessges.wordWrap=true;
   myScrollBar.scrollTarget  = TxtMessges;
   myScrollBar.y=TxtMessges.y;
   myScrollBar.x=TxtMessges.width;
   myScrollBar.height= TxtMessges.height;
   addChild(TxtMessges);
   addChild(myScrollBar);
   xmlLoader.removeEventListener(Event.COMPLETE,gotXML);
   createAddDetailsForm();
  }
  function createAddDetailsForm() {
   var BoxBG = createRectangle(400,340,0xF8F8F8,.9);
   var AddMsgButton = createRectangle(80,20,0xCCCCCC,1);
   AddMsgButton.name="AddMsgButton";
   var TextAddMsgButton= new TextField();
   TextAddMsgButton.autoSize = TextFieldAutoSize.LEFT;
   TextAddMsgButton.selectable=false;
   TextAddMsgButton.text = "Add Message";
   AddMsgButton.buttonMode=true;
   AddMsgButton.addEventListener(MouseEvent.CLICK,AddMsgButtonClickHandler);
   AddMsgButton.addChild(TextAddMsgButton);
   AddMsgButton.x=BoxBG.width- AddMsgButton.width;
   AddMsgButton.y=BoxBG.height- AddMsgButton.height;
   AddMsgButton.mouseChildren=false;
   BoxBG.addChild( AddMsgButton);
   var LabelName = new TextField();
   var LableEmail= new TextField();
   var LabelMessage = new TextField();
   var LabelTime = new TextField();
   var InputName = new TextField();
   var InputEmail = new TextField();
   var InputMessage = new TextField();
   var InputTime = new TextField();
   LabelName.text = "Name" ;
   LableEmail.text="Email" ;
   LabelMessage.text ="Message" ;
   LabelTime.text = "Time" ;
 
   LabelName.y=50;
   LableEmail.y= 100;
   LabelMessage.y = 150;
   LabelTime.y = 220;
   LabelName.x=50;
   LableEmail.x= 50;
   LabelMessage.x = 50;
   LabelTime.x = 50;
   InputName.y = 50;
   InputEmail.y = 100;
   InputMessage.y = 150;
   InputTime.y = 220;
   InputName.x = 100;
   InputEmail.x = 100;
   InputMessage.x = 100;
   InputTime.x = 100;
   InputName.width = 200;
   InputEmail.width = 200;
   InputMessage.width = 200;
   InputTime.width= 200;
   InputName.height = 20;
   InputEmail.height = 20;
   InputMessage.height = 50;
   InputMessage.wordWrap=true;
   InputTime.height= 20;
   InputName.type = TextFieldType.INPUT;
   InputEmail.type = TextFieldType.INPUT;
   InputMessage.type = TextFieldType.INPUT;
   /*
   InputName.border = true;
   InputEmail.border = true;
   InputMessage.border = true;
   InputTime.border = true;*/
   InputName.background = true;
   InputEmail.background = true;
   InputMessage.background = true;
   InputTime.background = true;
   BoxBG.addChild(LabelName);
   BoxBG.addChild(LableEmail);
   BoxBG.addChild(LabelMessage);
   BoxBG.addChild(LabelTime);
   BoxBG.addChild(InputName);
   BoxBG.addChild(InputEmail);
   BoxBG.addChild(InputMessage);
   BoxBG.addChild(InputTime);
   var SendButton = createRectangle(80,20,0xCCCCCC,1);
   var TextSendButton= new TextField();
   TextSendButton.autoSize = TextFieldAutoSize.LEFT;
   TextSendButton.selectable=false;
   TextSendButton.text = "Send";
   SendButton.x=AddMsgButton.x;
   SendButton.y= AddMsgButton.y-SendButton.height-10;
   SendButton.addChild(TextSendButton);
   BoxBG.addChild(SendButton);
   SendButton.mouseChildren=false;
   SendButton.buttonMode=true;
   SendButton.addEventListener(MouseEvent.CLICK,SendButtonClickHandler);
   SendButton.addEventListener(MouseEvent.CLICK,AddMsgButtonClickHandler);
   form =BoxBG;
   form .y=30-form .height;
   addChild(form );
  }
  function createRectangle(Width:int,Height:int,color:Number,Alpha:Number):MovieClip {
   var MyRect=new MovieClip();
   MyRect.graphics.beginFill(color,Alpha);
   MyRect.graphics.drawRect(0,0,Width,Height);
   MyRect.graphics.endFill();
   return MyRect;
  }
  function AddMsgButtonClickHandler(e:MouseEvent) {
   if (form .y==0) {
    TweenHandler(form ,form.y,(form.y-form .height)+30,"y");
    form.getChildAt(0).getChildAt(0).text="Add Message";
   } else {
    TweenHandler(form ,form.y,0,"y");
    form.getChildAt(0).getChildAt(0).text="Close";
    var myDate1:Date = new Date();
    form.getChildAt(8).text= myDate1;
   }
  }
  function SendButtonClickHandler(e:MouseEvent):void {
   if (form.getChildAt(5).text!=""&&form.getChildAt(6).text!=""&&form.getChildAt(7).text!=""&&form.getChildAt(8).text!="") {
    var newItem:XML = 
    <Guest >
    <name>{form.getChildAt(5).text}</name>
    <email>{form.getChildAt(6).text}</email>
    <message>{form.getChildAt(7).text}</message>
    <time>{form.getChildAt(8).text}</time>
    </Guest>;
    xmlData.appendChild(newItem);
    callServer(xmlData);
    /////////////////////////
    TxtMessges.appendText("Message "+MSGCounter++ +"\n");
    TxtMessges.appendText("Name - ");
    TxtMessges.appendText(form.getChildAt(5).text);
    TxtMessges.appendText("\nEmail - ");
    TxtMessges.appendText(form.getChildAt(6).text);
    TxtMessges.appendText("\nMessage - ");
    TxtMessges.appendText(form.getChildAt(7).text);
    TxtMessges.appendText("\nTime - ");
    TxtMessges.appendText(form.getChildAt(8).text);
    TxtMessges.appendText("\n------------------------------------------------------------------------\n");
    TxtMessges.appendText("\n\n");
    ////////////////////////////////////
   }
  }
  function TweenHandler(myObject:MovieClip,Start:Number,Stop:Number,Property:String) {
   var myTween:Tween = new Tween(myObject, Property, Regular.easeInOut, Start, Stop, .2, true);
  }
  function callServer(XMLData:XML):void {
   var urlRequest:URLRequest = new URLRequest("processXML.php");
   var urlParams:URLVariables = new URLVariables();
   urlParams.xmlVal = XMLData;
   urlRequest.method = URLRequestMethod.POST;
   urlRequest.data = urlParams;
   var loader:URLLoader = new URLLoader();
   loader.load(urlRequest);
  }
 }
}

Onam Greetings

2008-09-09T06:09:00.000-07:00

Flash CS3 - Flash AutoComplete And Cookie

2008-09-09T00:03:00.000-07:00

Try it here

Download AutoComplete.zip

ActionScript Code:

package {
 import flash.display.*;
 import flash.events.*;
 import flash.net.*;
 import flash.text.*;
 import fl.data.DataProvider;
 public class cookies extends Sprite {
  var soDomain:String="FlashAutoCompleteCookieTest";
  //Returns a reference to a locally persistent shared object that is only available to the current client. If the shared object does not already exist, this method creates one. If any values passed to getLocal() are invalid or if the call fails, Flash Player throws an exception. 
  var so:SharedObject=SharedObject.getLocal(soDomain);
  var ObjectCount=new int;
  var CookieArray:Array = new Array();
  public function cookies():void {
   saveBtn.addEventListener(MouseEvent.CLICK,saveHandler);
   deleteBtn.addEventListener(MouseEvent.CLICK,deleteHandler);
   if (so.data['ObjectTotal'] == undefined) {
    so.data['ObjectTotal']=0;
    so.flush();
   }
   ObjectCount=so.data['ObjectTotal'];
   readObject();
   UpdateData();
  }
  function addDataToObject(DataName:String,DataValue:String):void {
   so.data[DataName]=DataValue;
   so.flush();
   CookieArray.push(DataValue);
   //trace("Value added: " + so.data[DataName]);
   UpdateData();
  }
  function deleteObject():void {
   so.clear();
   //trace("Shared Object deleted");
   so.data['ObjectTotal']=0;
   CookieArray.splice(0 ,CookieArray.length);
   CookieList.removeAll();
   autoComplete.text="";
   autoComplete.dataProvider = new DataProvider(CookieArray);
  }
  function readObject():void {
   for (var i:int=0; i < ObjectCount; i++) {
    //trace("Shared Object Value : " + so.data[i]);
    CookieArray.push(so.data[i]);
   }
  }
  //Handlers
  function saveHandler(e:MouseEvent):void {
   if ((CookieArray.indexOf(autoComplete.text))==-1&&autoComplete.text!="") {
    addDataToObject(String(ObjectCount),autoComplete.text);
    so.data['ObjectTotal']=++ObjectCount;
    so.flush();
   } else {
    //trace("exist");
   }
  }
  function deleteHandler(e:MouseEvent):void {
   deleteObject();
  }
  function UpdateData() {
   CookieList.dataProvider = new DataProvider(CookieArray);
   autoComplete.dataProvider = new DataProvider(CookieArray);
  }
 }//
}//

Flash CS3 - Text With Blur Effect - (Move your mouse over the text !!)

2008-08-29T01:15:00.000-07:00

Move your mouse over the text !!

ActionScript Code:

stage.frameRate=30;
var dragFactor:Number=.15;
var newFormat:TextFormat = new TextFormat();
newFormat.size=20;
newFormat.bold=true;
newFormat.color=0xFF0000;
newFormat.align=TextFormatAlign.LEFT;
var MyTextField = new TextField();
MyTextField.text="AS3 ROCKS!!";
MyTextField.width=200;
MyTextField.selectable=false;
MyTextField.setTextFormat(newFormat);
addChild(MyTextField);
stage.addEventListener(Event.ENTER_FRAME,MOUSE_MOVE_Handler);
function MOUSE_MOVE_Handler(e:Event):void {
 var xPos:Number=mouseX;
 var yPos:Number=mouseY;
 xPos=MyTextField.x;
 xPos -= (xPos-mouseX) * this.dragFactor;
 yPos=MyTextField.y;
 yPos -= (yPos-mouseY) * this.dragFactor;
 MyTextField.x=xPos;
 MyTextField.y=yPos;
 MyTextField.filters=[new BlurFilter(Math.abs(xPos-mouseX),Math.abs(yPos-mouseY),1)];
}

Flash CS3 - Sliding Menu

2008-08-27T03:06:00.000-07:00

Download SlidingMenu.zip

import fl.transitions.Tween;

import fl.transitions.easing.*;

import fl.transitions.TweenEvent;

var i = new int;

var MyRoot = root;

//edit this no

var BoxSize:Number = 100;

//edit this no

var BoxNum:Number = 4;

var MainMenu = createManu();

var MenuMask = createBox(BoxSize,0xFFCC00);

MainMenu.mask = MenuMask;

MainMenu.animation=1;

function createManu():MovieClip {

var menu = new MovieClip();

for (i=0; i<BoxNum; i++) {

var MenuItem = createBox(BoxSize,0xFFCC00/i);

menu.addChild(MenuItem);

MenuItem.x=BoxSize*i;

var newFormat:TextFormat = new TextFormat();

newFormat.size=BoxSize;

newFormat.color=0xFFFFFF;

newFormat.align = TextFormatAlign.CENTER;

var target = MenuItem.getChildAt(0);

target.text = i;

target.width = BoxSize;

target.height = BoxSize;

target.x=0;

target.y=0;

target.selectable = false;

target.setTextFormat(newFormat);

target.mouseEnabled = false;

MenuItem.id=i;

MenuItem.addEventListener(MouseEvent.CLICK,ClickHandler);

MenuItem.buttonMode = true;

}

return menu;

}

var MenuButton:MovieClip = createManu();

addChild(MenuButton);

MenuButton.scaleX=.25;

MenuButton.scaleY=.25;

MenuButton.x=stage.stageWidth/2-MenuButton.width/2;

MenuButton.y=BoxSize+10;

addChild(MainMenu);

MainMenu.x=MenuButton.x;

MainMenu.y=10;

MainMenu.enabled = false;

MenuMask.y=MainMenu.y;

MenuMask.x= MainMenu.x;

addChild(MenuMask);

function createBox(Size:Number,clr:Number):MovieClip {

var box = new MovieClip();

var TextInBox = new TextField();

box.graphics.lineStyle(2,0x999999);

box.graphics.beginFill(clr,1);

box.graphics.drawRect(0,0,Size,Size);

box.graphics.endFill();

box.addChild(TextInBox);

return box;

}

function TweenHandler(MyObject:MovieClip,Start:Number,End:Number ):void {

var MyTween:Tween = new Tween(MyObject, "x", Regular.easeOut, Start, End, 2, true);

MyTween.addEventListener(TweenEvent.MOTION_FINISH,FinishHandler);

MainMenu.animation=0;

}

function FinishHandler(e:TweenEvent):void {

MainMenu.animation=1;

}

function ClickHandler(e:MouseEvent ):void {

TweenHandler(MainMenu,MainMenu.x,(MenuButton.x)-(BoxSize*e.target.id));

}

var LeftArrow = CreateArrow();

addChild(LeftArrow);

LeftArrow.y=MenuButton.y+10;

LeftArrow.x=MenuButton.x-LeftArrow.width;

var RightArrow = CreateArrow();

addChild(RightArrow);

RightArrow.y=MenuButton.y+10;

RightArrow.x=LeftArrow.x+MenuButton.width*2+10;

RightArrow.rotation = 180;

function CreateArrow():MovieClip {

var Arrow= new MovieClip();

Arrow.graphics.lineStyle(1,0x000000);

Arrow.graphics.beginFill(0xFF6600,1);

Arrow.graphics.lineTo(30,-20);

Arrow.graphics.lineTo(20,-3);

Arrow.graphics.lineTo(50,-18);

Arrow.graphics.lineTo(53,15);

Arrow.graphics.lineTo(20,4);

Arrow.graphics.lineTo(30,20);

Arrow.graphics.lineTo(0,0);

Arrow.buttonMode = true;

return Arrow;

}

LeftArrow.addEventListener(MouseEvent.CLICK,NavigateLeft);

RightArrow.addEventListener(MouseEvent.CLICK,NavigateRight);

function NavigateLeft(e:MouseEvent ):void {

if ((MainMenu.x>(MenuButton.x-MainMenu.width)+(BoxSize*2))&&MainMenu.animation==1) {

TweenHandler(MainMenu,MainMenu.x,MainMenu.x-BoxSize);

}

}

function NavigateRight(e:MouseEvent ):void {

if ((MainMenu.x<(MenuButton.x))&&MainMenu.animation==1) {

TweenHandler(MainMenu,MainMenu.x,MainMenu.x+BoxSize);

}

}

Flash CS3 - Drag And Drop (Simple Game)

2008-08-27T02:46:00.000-07:00

Download DragAndDrop.zip

Paste this code in your AS panel . You dont need to create anything on the stage

import fl.transitions.Tween;

import fl.transitions.easing.*;

stage.frameRate=30;

var TargetCircle = CreateCircle(0x00FF00,100);

TargetCircle.x=250;

TargetCircle.y=200;

addChild(TargetCircle);

var SmallCircle = CreateCircle(0xFF6600,10);

SmallCircle.x=50;

SmallCircle.y=200;

SmallCircle.buttonMode = true;

SmallCircle.addEventListener(MouseEvent.MOUSE_DOWN,DOWNHandler);

SmallCircle.addEventListener(MouseEvent.MOUSE_UP,UPHandler);

addChild(SmallCircle);

function DOWNHandler(e:MouseEvent) {

e.target.startDrag();

}

function UPHandler(e:MouseEvent) {

e.target.stopDrag();

if (SmallCircle.hitTestObject(TargetCircle)==false) {

TweenHandler();

}

}

function CreateCircle(color:Number,radius:Number):MovieClip {

var circle:MovieClip = new MovieClip;

circle.graphics.beginFill(color,1);

circle.graphics.drawCircle(0,0,radius);

circle.graphics.endFill();

return circle;

}

function TweenHandler() {

var tweenX = new Tween(SmallCircle,"x",Regular.easeInOut,SmallCircle.x,50,1,true);

var tweenY = new Tween(SmallCircle,"y",Regular.easeInOut,SmallCircle.y,200,1,true);

}

Flash CS3 - Rotating Sunrays Animation

2008-08-22T00:05:00.000-07:00

Copy and paste this AS3 code to the first frame of your flash CS3 document. You don't need to create anything on the stage

ActionScript Code:

function CreateRays():Shape {
 var ray:Shape = new Shape();
 ray.graphics.beginFill(0xFF9900,.5);
 ray.graphics.lineStyle(1,0xFF9900,.5);
 ray.graphics.lineTo(600,-20);
 ray.graphics.lineTo(600,20);
 ray.graphics.lineTo(0,0);
 ray.graphics.endFill();
 return ray;
}
var sun:Shape = new Shape();
sun.graphics.beginFill(0xFF9900,1);
sun.graphics.drawCircle(0,0,30);
sun.graphics.endFill();
//edit this no to change the no of rays :-)
var SunaRays:Number=25;
var rayShapes = new Shape();
var SunGlow:MovieClip = new MovieClip();
for (var i:int = 1; i<=SunaRays; i++) {
 rayShapes=CreateRays();
 rayShapes.rotation=360/(SunaRays)*i;
 SunGlow.addChild(rayShapes);
}
SunGlow.addChild(sun);
addChild(SunGlow);
SunGlow.x=stage.stageWidth/2;
SunGlow.y=stage.stageHeight/2;
//you can change fps here
stage.frameRate=30;
stage.addEventListener(Event.ENTER_FRAME,rotateSun);
function rotateSun(e:Event):void {
 //you change speed here
 SunGlow.rotation+=1;
}

Flash CS3 - Flash website with a simple preloader

2008-08-19T07:04:00.000-07:00

download preloader.zip

//////////////////////////////////

stop();

var Circle = new Shape();

Circle.graphics.lineStyle(5,0x00FF00);

Circle.graphics.drawCircle(100, 100, 50);

var Line = new Shape();

Line.graphics.lineStyle(5,0x00FF00);

Line.graphics.lineTo(0,-40);

Line.x=100;

Line.y=100;

var Status = new TextField();

Status.autoSize =TextFieldAutoSize.CENTER;

Status.selectable = false;

Status.y = 100;

Status.x = 100;

addChild(Circle);

addChild(Line);

addChild(Status);

function PreLoader() {

this.loaderInfo.addEventListener(Event.COMPLETE, initApplication);

this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, showProgress);

}

function showProgress(theProgress:ProgressEvent):void {

var percent:Number =(theProgress.bytesLoaded) / (theProgress.bytesTotal)*100;

Line.rotation=percent*3.6;

Status.text = Math.round(percent)+" %";

}

function initApplication(myEvent:Event):void {

removeChild(Circle);

removeChild(Line);

removeChild(Status);

gotoAndStop("frm_main");

}

PreLoader();

//////////////////////////////////

Flash CS3 - AS3 Counter

2008-08-19T05:18:00.000-07:00

Copy and paste this AS3 code to the first frame of your flash CS3 document. You don't need to create anything on the stage

import fl.transitions.Tween;

import fl.transitions.TweenEvent;

import fl.transitions.easing.*;

var counter:int = 0;

var MyFormat:TextFormat=new TextFormat;

MyFormat.bold=true;

MyFormat.font="Arial";

MyFormat.size=50;

MyFormat.color=0x000000;

function createShape():MovieClip {

var shape = new MovieClip();

var shapeBG = new MovieClip();

var shapeMask = new MovieClip();

var shapeText = new TextField();

shapeText.defaultTextFormat=MyFormat;

shapeText.text="0";

shapeText.autoSize =TextFieldAutoSize.CENTER;

shapeText.selectable = false;

shapeText.name = "shapeText";

shapeText.y = -5;

shapeText.x = 10;

shapeText.mask = shapeMask;

shapeText.name = "shapeText";

shapeBG.graphics.beginFill(0xE6E6E6, 1);

shapeBG.graphics.drawRoundRect(0, 0, 50, 50, 25, 25);

shapeBG.graphics.endFill();

shapeBG.name = "shapeBG";

shapeMask.graphics.beginFill(0x00CCCC, 1);

shapeMask.graphics.drawRoundRect(0, 0, 50, 50, 25, 25);

shapeMask.graphics.endFill();

shapeMask.name = "shapeMask";

shape.addChild(shapeBG);

shape.addChild(shapeMask);

shape.addChild(shapeText);

shape.name = "shape";

return shape;

}

var distance:int = 60;

var shape1= createShape();

addChild(shape1);

shape1.x=distance*2;

shape1.y=10;

var shape2= createShape();

addChild(shape2);

shape2.x=distance*1;

shape2.y=10;

var shape3= createShape();

addChild(shape3);

shape3.x=distance*0;

shape3.y=10;

var time:int = 1000;

var MyTimer:Timer = new Timer(time);

MyTimer.addEventListener(TimerEvent.TIMER, runOdometer);

MyTimer.start();

var target1 = shape1.getChildAt(2);

var target2 = shape2.getChildAt(2);

var target3 = shape3.getChildAt(2);

function positionFn(TweenMC:TextField,Start:int,Stop:int):void {

var tween_handler = new Tween(TweenMC,"y",None.easeInOut,Start,Stop,time/(time*6),true);

tween_handler.addEventListener(TweenEvent.MOTION_FINISH,UpdateStatus);

}

function positionFn2(TweenMC:TextField,Start:int,Stop:int):void {

var tween_handler = new Tween(TweenMC,"y",None.easeInOut,Start,Stop,time/(time*6),true);

}

function UpdateStatus(e:TweenEvent) {

target1.text = counter;

positionFn2(target1,32,-5);

if (counter>9) {

target2.text=int(target2.text)+1;

positionFn2(target2,32,-5);

counter=0;

if (int(target2.text)>9) {

target2.text="0";

target3.text=int(target3.text)+1;

positionFn2(target3,32,-5);

if (int(target3.text)>9) {

target3.text="0";

}

}

}

}

Flash CS3 - Random Image Loader With Progress Bar

2008-08-06T03:30:00.000-07:00

ImageLoader.zip

package {

import flash.display.*;

import flash.events.*;

import flash.net.*;

import flash.text.*;

import fl.controls.*;

import fl.transitions.Tween;

import fl.transitions.easing.*;

public class ImageLoader extends Sprite {

var imageLoader:Loader = new Loader();

var imagesArr:Array=new Array("image1.jpg","image2.jpg","image3.jpg","image4.jpg","image5.jpg");

var mc_ProgressBar:MovieClip = new MovieClip();

var StatusBar:MovieClip = new MovieClip();

var txtStatus:TextField = new TextField();

var LoadBtn = new Button();

public function ImageLoader():void {

addChild(imageLoader);

addChild(mc_ProgressBar);

addChild(LoadBtn);

LoadBtn.y=270;

LoadBtn.label ="Load Image";

LoadBtn.width = 80;

imageLoader.alpha=0;

DrawProgressBar();

imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);

imageLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);

LoadBtn.addEventListener(MouseEvent.CLICK,loadHandler);

}

function completeHandler(event:Event):void {

var imageTween:Tween = new Tween(imageLoader, "alpha", Strong.easeOut, 0, 1, 3, true);

txtStatus.text ="Image has been loaded successfully";

}

function progressHandler(event:ProgressEvent):void {

var CurrentStatus:String = String(Math.round(event.bytesLoaded * 100 / event.bytesTotal));

txtStatus.text ="Loading "+ CurrentStatus + " %";

StatusBar.width=(event.bytesLoaded * 100 / event.bytesTotal)*2;

}

function loadHandler(event:MouseEvent ):void {

var index:Number = Math.floor(Math.random() * imagesArr.length);

imageLoader.load(new URLRequest("images/"+imagesArr[index]));

}

function DrawProgressBar():void {

mc_ProgressBar.x=100;

mc_ProgressBar.y=280;

StatusBar.graphics.beginFill(0xCCCCCC, 1);

StatusBar.graphics.drawRect(0, 0, 200,5);

StatusBar.graphics.endFill();

StatusBar.width=1;

mc_ProgressBar.addChild(StatusBar);

var StatusBox:MovieClip = new MovieClip();

StatusBox.graphics.lineStyle(1, 0x000000);

StatusBox.graphics.drawRect(0, 0, 200,5);

mc_ProgressBar.addChild(StatusBox);

mc_ProgressBar.addChild(txtStatus);

txtStatus.width =200;

txtStatus.y =-15;

}

}

}

FlashCS3 - Full Screen Flash Website - II (True Full Screen)

2008-07-22T06:06:00.001-07:00

Click HERE For Full Screen Window

Click anywhere on the stage after you click on the link above.

Source File - fullScreen2.zip

package {

import flash.display.*;

import flash.events.*;

import fl.transitions.Tween;

import fl.transitions.TweenEvent;

import fl.transitions.easing.*;

import flash.text.*;

public class fullScreen2 extends MovieClip {

public function fullScreen2():void {

stage.align=StageAlign.TOP_LEFT;

stage.scaleMode=StageScaleMode.NO_SCALE;

stage.addEventListener(Event.RESIZE,stageResized);

StageElementMiddle.x=stage.stageWidth / 2;

StageElementMiddle.y=stage.stageHeight / 2;

ArrangeItems();

stage.addEventListener(MouseEvent.CLICK,FullScreen);

}

function stageResized(e:Event):void {

ArrangeItems();

}

function positionFn(TweenMC:MovieClip,StageWidth:Number,StageHeight:Number):void {

var tween_handler_1 = new Tween(TweenMC,"x",Elastic.easeInOut,TweenMC.x,StageWidth,1,true);

var tween_handler_2 = new Tween(TweenMC,"y",Elastic.easeInOut,TweenMC.y,StageHeight,1,true);

tween_handler_1.addEventListener(TweenEvent.MOTION_FINISH,UpdateStatus);

tween_handler_2.addEventListener(TweenEvent.MOTION_FINISH,UpdateStatus);

}

function UpdateStatus(e:TweenEvent):void {

StageElementMiddle.XTxt.text="X= " + Math.floor(StageElementMiddle.x);

StageElementMiddle.YTxt.text="Y= " + Math.floor(StageElementMiddle.y);

}

function ArrangeItems():void {

Header.x=0;

Footer.x=0;

Header.y=0;

Footer.y=stage.stageHeight - Footer.height;

Header.width=stage.stageWidth;

Footer.width=stage.stageWidth;

StageElementLeft.x=0 + StageElementLeft.width / 2;

StageElementLeft.y=stage.stageHeight / 2;

StageElementLeft.XTxt.text="X= " + Math.floor(StageElementLeft.x);

StageElementLeft.YTxt.text="Y= " + Math.floor(StageElementLeft.y);

StageElementRight.x=stage.stageWidth - StageElementRight.width / 2;

StageElementRight.y=stage.stageHeight / 2;

StageElementRight.XTxt.text="X= " + Math.floor(StageElementRight.x);

StageElementRight.YTxt.text="Y= " + Math.floor(StageElementRight.y);

StageElementTop.x=stage.stageWidth / 2;

StageElementTop.y=StageElementTop.height / 2;

StageElementTop.XTxt.text="X= " + Math.floor(StageElementTop.x);

StageElementTop.YTxt.text="Y= " + Math.floor(StageElementTop.y);

positionFn(StageElementMiddle,stage.stageWidth / 2,stage.stageHeight / 2);

StageElementMiddle.XTxt.text="X= " + Math.floor(StageElementMiddle.x);

StageElementMiddle.YTxt.text="Y= " + Math.floor(StageElementMiddle.y);

StageElementBottom.x=stage.stageWidth / 2;

StageElementBottom.y=stage.stageHeight - StageElementBottom.height / 2;

StageElementBottom.XTxt.text="X= " + Math.floor(StageElementBottom.x);

StageElementBottom.YTxt.text="Y= " + Math.floor(StageElementBottom.y);

Swidth.text="Width = " + stage.stageWidth;

Sheight.text="Height = " + stage.stageHeight;

}

function FullScreen(e:MouseEvent):void {

stage['displayState'] = "fullScreen";

}

}

}

FlashCS3 - Full Screen Flash Website - I

2008-07-22T04:59:00.001-07:00

Click HERE For Full Screen Window

Source File - fullScreen1.zip

public function fullScreen1():void {

ArrangeItems();

}

function positionFn(TweenMC:MovieClip,StageWidth:Number,StageHeight:Number):void {

var tween_handler_1 = new Tween(TweenMC,"x",Elastic.easeInOut,TweenMC.x,StageWidth,1,true);

var tween_handler_2 = new Tween(TweenMC,"y",Elastic.easeInOut,TweenMC.y,StageHeight,1,true);

Header.x=0;

Footer.x=0;

Header.y=0;

Footer.y=stage.stageHeight - Footer.height;

Header.width=stage.stageWidth;

Footer.width=stage.stageWidth;

Swidth.text="Width = " + stage.stageWidth;

Sheight.text="Height = " + stage.stageHeight;

}

}

}

Flash CS3 – Using Arrow Keys To Move An Object

2008-07-22T02:22:00.000-07:00

Copy and paste this AS3 code to the first frame of your flash CS3 document.

var UrShape:Shape = new Shape();
addChild(UrShape);
UrShape.x = 250;
UrShape.y = 150;
UrShape.graphics.lineStyle(3, 0x000000);
UrShape.graphics.beginFill(0x9900FF, 1);
UrShape.graphics.drawRect(0, 0, 50,50);
UrShape.graphics.endFill();
stage.addEventListener(KeyboardEvent.KEY_DOWN,MoveRectangle);

function MoveRectangle(keyEvent:KeyboardEvent):void {
switch (keyEvent.keyCode) {
case 37 ://left arrow
UrShape.x--;
break;
case 38 ://up arrow
UrShape.y--;
break;
case 39 ://right arrow
UrShape.x++;
break;
case 40 ://down arrow
UrShape.y++;
break;
default :
break;
}
}

Flash CS3 - Positioning An Object With Slider

2008-07-22T01:27:00.000-07:00

Copy and paste this AS3 code to the first frame of your flash CS3 document.

stage.frameRate=30;

var MyShape:Shape = new Shape();
MyShape.graphics.lineStyle(1, 0x000000);
MyShape.graphics.beginFill(0x6633CC, 1);
MyShape.graphics.drawCircle(0, 0, 50);
MyShape.graphics.endFill();
addChild(MyShape);
//////////////////
var xLine:Shape = new Shape();
xLine.graphics.lineStyle(1, 0x666666);
xLine.graphics.moveTo(30, 30);
xLine.graphics.lineTo(500, 30);
xLine.graphics.endFill();
addChild(xLine);
//////////
var yLine:Shape = new Shape();
yLine.graphics.lineStyle(1, 0x666666);
yLine.graphics.moveTo(30, 30);
yLine.graphics.lineTo(30, 350);
yLine.graphics.endFill();
addChild(yLine);
///////////
var xSlider:MovieClip = new MovieClip();
xSlider.x =xLine.width/2;
xSlider.y = 15;
xSlider.graphics.lineStyle(1, 0x000000);
xSlider.graphics.beginFill(0xFF6600, 1);
xSlider.graphics.drawRoundRectComplex(0, 0, 10, 30, 20, 20, 20, 20);
xSlider.graphics.endFill();
addChild(xSlider);
///////////
var ySlider:MovieClip = new MovieClip();
ySlider.x =15;
ySlider.y = yLine.height/2;
ySlider.graphics.lineStyle(1, 0x000000);
ySlider.graphics.beginFill(0xFF6600, 1);
ySlider.graphics.drawRoundRectComplex(0, 0, 30, 10, 20, 20, 20, 20);
ySlider.graphics.endFill();
addChild(ySlider);
///////////

MyShape.x = xSlider.x;
MyShape.y = ySlider.y;

xSlider.Status= 0;
ySlider.Status= 0;

xSlider.addEventListener(MouseEvent.MOUSE_DOWN,SliderDown);
ySlider.addEventListener(MouseEvent.MOUSE_DOWN,SliderDown);

stage.addEventListener(MouseEvent.MOUSE_UP,SliderUp);
stage.addEventListener(MouseEvent.MOUSE_UP,SliderUp);

function SliderDown(e:MouseEvent):void {
e.target.Status= 1;
}
function SliderUp(e:MouseEvent):void {
xSlider.Status= 0;
ySlider.Status= 0;
}

stage.addEventListener(MouseEvent.MOUSE_MOVE,StartDrag);

function StartDrag(e:MouseEvent):void {
if (xSlider.Status== 1) {
if (e.stageX>45&&e.stageX<xLine.width) {
xSlider.x =e.stageX-(xSlider.width/2);
MyShape.x=xSlider.x;

}
}
if (ySlider.Status== 1) {
if (e.stageY>45&&e.stageY<yLine.height) {
ySlider.y =e.stageY-(ySlider.height/2);
MyShape.y=ySlider.y ;
}
}
}

Flash CS3 - Walk Cycle

2008-07-18T06:25:00.000-07:00

walk_cycle.zip

Flash CS3 - Custom Mouse Pointer

2008-06-26T05:59:00.000-07:00

Click on each mouse pointer

pointer.as

package {
import flash.display.*;
import flash.events.*;
import flash.filters.*;
import flash.text.*;
import flash.ui.Mouse;
public class pointer extends Sprite {
//you can see them on the stage
var pnt_1= new Pointer_1();
var pnt_2= new Pointer_2();
var pnt_3= new Pointer_3();

//your current Mouse Pointer
var CurrentPointer = new MovieClip();

var Text1:TextField = new TextField();
var Text2:TextField = new TextField();
var Text3:TextField = new TextField();

var DropShadow:DropShadowFilter = new DropShadowFilter();

public function pointer():void {
//add three custom pointers on the stage
AddPointers();
AddText();
//give them a shadow effect
ApplyFilter();
//we use this id in function PointerListener()
pnt_1.id=1;
pnt_2.id=2;
pnt_3.id=3;
pnt_1.addEventListener(MouseEvent.CLICK, PointerListener);
pnt_2.addEventListener(MouseEvent.CLICK, PointerListener);
pnt_3.addEventListener(MouseEvent.CLICK, PointerListener);
addChild(CurrentPointer);
}
private function AddPointers():void {//add pointers and arrange them
pnt_1.x=450;
pnt_1.y=50;
pnt_2.x=450;
pnt_2.y=180;
pnt_3.x=450;
pnt_3.y=280;
addChild(pnt_1);
addChild(pnt_2);
addChild(pnt_3);
}

private function AddText():void {

var MyFormat:TextFormat=new TextFormat;
MyFormat.bold=true;
MyFormat.font="Arial";
MyFormat.size=30;
MyFormat.color=0x9933CC;
addChild(Text1);
addChild(Text2);
addChild(Text3);
Text1.defaultTextFormat=MyFormat;
Text2.defaultTextFormat=MyFormat;
Text3.defaultTextFormat=MyFormat;
Text1.selectable=false;
Text2.selectable=false;
Text3.selectable=false;
Text1.text = "Pointer 1";
Text2.text = "Pointer 2";
Text3.text = "Pointer 3";
Text1.x=250;
Text2.x=250;
Text3.x=250;
Text1.y=70;
Text2.y=170;
Text3.y=270;
Text1.width = 150;
Text2.width = 150;
Text3.width = 150;

}

private function ApplyFilter():void {

DropShadow.distance = 10;
DropShadow.alpha = .5;

pnt_1.filters = [DropShadow];
pnt_2.filters = [DropShadow];
pnt_3.filters = [DropShadow];
Text1.filters = [DropShadow];
Text2.filters = [DropShadow];
Text3.filters = [DropShadow];
}
private function PointerListener(Event:MouseEvent):void {
removeChild(CurrentPointer);
Mouse.hide();
switch (Event.target .id) {
case 1 :
CurrentPointer=new Pointer_1();
break;
case 2 :
CurrentPointer=new Pointer_2();
break;
case 3 :
CurrentPointer=new Pointer_3();
break;

}
CurrentPointer.filters = [DropShadow];
addChild(CurrentPointer);
CurrentPointer.x=Event.stageX;
CurrentPointer.y=Event.stageY;
stage.addEventListener(MouseEvent.MOUSE_MOVE,MovePointer);
}
private function MovePointer(event:MouseEvent):void {
CurrentPointer.x=event.stageX;
CurrentPointer.y=event.stageY;
}
}
}

Source File - CustomMousePointer.zip

Flash CS3 - A Simple Game

2008-06-25T05:53:00.001-07:00

game.as

package {
import flash.display.*;
import flash.ui.Mouse;
import flash.events.*;
import flash.text.*;
public class game extends Sprite {
var hits:int=0;
var misses:int=0;
var shots:int=0;
var cDepth:int=100;
var level:int=1;
var xSpeed:Number=3;
var stageWidth:Number=550;
var stageHeight:Number=300;

var AirCraft_MC:MovieClip = new MovieClip();

var AimMC:MovieClip=new Aim_mc;//MovieClip to aim your gun - we import this MovieClip direct from Lib
var stats_txt:TextField=new TextField;// create a text field to display the player's statistics.
public function game():void {
black_mc.start_btn.addEventListener(MouseEvent.MOUSE_DOWN ,StartFunction);
black_mc.start_btn.buttonMode=true;
}
private function StartFunction(event:MouseEvent ):void {
black_mc.visible =false;
aim();
stats_txt_fn();
stage.addEventListener(MouseEvent.MOUSE_MOVE,HideMouse);
stage.addEventListener(MouseEvent.MOUSE_DOWN,GunShot);
stage.addEventListener(Event.ENTER_FRAME,addAirCrafts);
}
private function aim() {
AimMC.mouseEnabled=false;
addChild(AimMC);
}
private function stats_txt_fn() {
var MyFormat:TextFormat=new TextFormat;
MyFormat.bold=true;
MyFormat.font="Arial";
MyFormat.size=12;
MyFormat.color=0xFFFFFF;
stats_txt.x=10;
stats_txt.y=0;
stats_txt.width=550;
stats_txt.height=20;
addChild(stats_txt);
// apply the TextFormat to the text field.
stats_txt.defaultTextFormat=MyFormat;
stats_txt.selectable=false;
updateStats();
}
private function HideMouse(event:MouseEvent):void {
Mouse.hide();
AimMC.x=event.stageX;
AimMC.y=event.stageY;
}
private function GunShot(event:MouseEvent):void {
shots++;
updateStats();
}
private function updateStats() {
var targetsHit:Number=Math.round(( hits * 100)/(hits+misses));
var accuracy:Number=Math.round( (hits * 100)/shots);
if (isNaN(targetsHit)) {
targetsHit=0;
}
if (isNaN(accuracy)) {
accuracy=0;
}
stats_txt.text="shots:" + shots + "\t" + "hits: " + hits + "\t" + "misses: " + misses + "\t" + "targets hit: " + targetsHit + "%" + "\t" + "accuracy: " + accuracy + "%" + "\t" + "level:" + level;
}
//new aircrafts are constantly added to the game
private function addAirCrafts(event:Event):void {
// randomly add new target's to the Stage.
if (randNum(1,40) == 1) {
var Current_MC:MovieClip;
// attach a new instance of the AirCraft instance from the library onto the Stage, and give it a unique depth.
var randomAirCraftNum:Number=randNum(1,2);
switch (randomAirCraftNum) {
case 1 :
Current_MC=new AirCraft1_mc ;
break;
case 2 :
Current_MC=new AirCraft2_mc ;
break;
default :
return;
break;
}
cDepth++;
// set the starting postition of the current target movie clip so it is just off to the left of the Stage.
Current_MC.x=- Current_MC.width;
//This is used to set the current movie clip's scale & speed
var scale:int=randNum(1,3);
//set the _xscale and _yscale properties of the current movie clip.
Current_MC.scaleX=1 - scale / 10;
Current_MC.scaleY=1 - scale / 10;
Current_MC.speed=xSpeed + randNum(0,3) + level;
//instead of all targets flying along the same path,they vary their vertical position slightly.
Current_MC.y=Math.round(Math.random() * 50) + 50;
Current_MC.name="AirCraft" + cDepth;
// Update the target's position on the Stage.
Current_MC.addEventListener(Event.ENTER_FRAME,AirCraft_EnterFrameHandler);
Current_MC.addEventListener(Event.ENTER_FRAME, AirCraft_Remove);
Current_MC.addEventListener(MouseEvent.CLICK, AirCraft_ClickHandler);
addChild(Current_MC);
//swap the custom cursor to the higher depth
swapChildren(Current_MC,AimMC);
}
}
// create a function that returns a random integer
private function randNum(minNum:Number,maxNum:Number):Number {
return Math.floor(Math.random() * maxNum - minNum + 1) + minNum;
}
private function AirCraft_EnterFrameHandler(event:Event):void {
AirCraft_MC=event.currentTarget as MovieClip;
// move the target horizontally along the Stage.
AirCraft_MC.x+= AirCraft_MC.speed;
// slightly decrement the _y position of the current target movie clip.
AirCraft_MC.y-= 0.4;

}
//delete the instance.
function AirCraft_Remove(event:Event):void {
if (AirCraft_MC.x > stageWidth) {
misses++;
updateStats();
//trace(AirCraft_MC.name);
removeChild(AirCraft_MC);
AirCraft_MC.removeEventListener(Event.ENTER_FRAME,AirCraft_Remove);
AirCraft_MC.removeEventListener(Event.ENTER_FRAME, AirCraft_EnterFrameHandler);

} else if (AirCraft_MC.y > stageHeight) {
removeChild(AirCraft_MC);
AirCraft_MC.removeEventListener(Event.ENTER_FRAME,AirCraft_Remove);
AirCraft_MC.removeEventListener(Event.ENTER_FRAME, AirCraft_EnterFrameHandler);

}
}
// when we hit on the airCraft
function AirCraft_ClickHandler(event:MouseEvent):void {
var Clicked_AirCraft_MC:MovieClip = event.currentTarget as MovieClip;
// update the player's stats
hits++;
if ((hits%40) == 0) {
level++;
}
updateStats();
//go to the movie clip's label named "hit"
Clicked_AirCraft_MC.gotoAndPlay("hit");
// create an onEnterFrame event for the current movie clip instance.
Clicked_AirCraft_MC.addEventListener(Event.ENTER_FRAME, AirCraft_HitEnterFrameHandler);
//delete the onPress event handler.
Clicked_AirCraft_MC.removeEventListener(MouseEvent.CLICK, AirCraft_ClickHandler);

}
function AirCraft_HitEnterFrameHandler(event:Event):void {
var AirCraft_Damage:MovieClip = event.currentTarget as MovieClip;
// animate the target falling from the sky.
var gravity:int = 10;
var ymov:int = AirCraft_Damage.y + gravity;
// increment the rotation of the current movie clip clock-wise
AirCraft_Damage.rotation += 20;
// falling from the sky instead of just dropping straight down.
AirCraft_Damage.x += xSpeed;
AirCraft_Damage.y = ymov;

}

}
}

Flash CS3 and XML - Loading XML in Flash

2008-06-24T03:14:00.001-07:00

View PersonalDetails.xml

loadxml.as

package {
import flash.display.*;
import flash.net.*;
import flash.events.*;
import fl.controls.DataGrid;
import fl.containers.UILoader;
import flash.text.*;
public class loadxml extends Sprite {
var xmlFile:String="PersonalDetails.xml";
var datagrid=new DataGrid;
var imgLoader=new UILoader;
var nameTxt=new TextField;
var occupationTxt=new TextField;
var ageTxt=new TextField;
var emailTxt=new TextField;
public function loadxml():void {
callBtn.addEventListener(MouseEvent.CLICK,callServer);
}
function callServer(e:MouseEvent):void {
var urlRequest:URLRequest=new URLRequest(xmlFile);
var loader:URLLoader=new URLLoader;
loader.addEventListener(Event.COMPLETE,xmlLoaded);
loader.load(urlRequest);
}
function xmlLoaded(e:Event):void {
var loader:URLLoader=URLLoader(e.target);
var xml:XML=new XML(loader.data);
createDataGrid();
createTextFields();
createImageLoader();
// loop through the details and insert each one into the DataGrid
for each (var item:XML in xml..person) {
var strName:String=item.name.toString();
var strOccupation:String=item.occupation.toString();
var strAge:String=item.age.toString();
var strEmail:String=item.email.toString();
var strImage:String = item.image.toString();
datagrid.addItem({Name:strName,Occupation:strOccupation,Age:strAge,Email:strEmail,Image:strImage});
}
}
private function createDataGrid():void {

datagrid.move(10,40);
datagrid.width=500;
datagrid.rowCount=7;
datagrid.columns=["Name","Occupation","Age","Email"];
datagrid.addEventListener(Event.CHANGE,gridItemSelected);
datagrid.minColumnWidth=datagrid.width / 3;
addChild(datagrid);
}
private function createTextFields():void {
nameTxt.x=10;
ageTxt.x=10;
occupationTxt.x=10;
emailTxt.x=10;
nameTxt.autoSize=TextFieldAutoSize.LEFT;
ageTxt.autoSize=TextFieldAutoSize.LEFT;
occupationTxt.autoSize=TextFieldAutoSize.LEFT;
emailTxt.autoSize=TextFieldAutoSize.LEFT;

nameTxt.y=datagrid.height + 50;
ageTxt.y=nameTxt.y + 25;
occupationTxt.y=ageTxt.y + 25;
emailTxt.y=occupationTxt.y + 25;

addChild(nameTxt);
addChild(ageTxt);
addChild(occupationTxt);
addChild(emailTxt);
}
private function gridItemSelected(e:Event):void {

nameTxt.text="Name: " + e.target.selectedItem.Name;
ageTxt.text="Age: " + e.target.selectedItem.Age ;
occupationTxt.text="Occupation: " + e.target.selectedItem.Occupation;
emailTxt.text="Email: " + e.target.selectedItem.Email;

imgLoader.source="images/"+e.target.selectedItem.Image;

}
private function createImageLoader():void {

imgLoader.move(10,40);
imgLoader.y=nameTxt.y;
imgLoader.x=200;
imgLoader.width=95;
imgLoader.height=100;
addChild(imgLoader);
}
}//class loadxml ends
}//package ends

Source File - Loading_XML.zip

Flash CS3 and PHP - File Upload

2008-06-23T04:41:00.001-07:00

ActionScript 3

package {
import flash.display.Sprite;
import flash.text.TextField;
import flash.events.*;
import flash.net.*;
import fl.controls.Button;

public class FileUpload extends Sprite {
private var _output:TextField;
private var _fileReference:FileReference;
var browseButton:Button = new Button();
var uploadButton:Button = new Button();
public function FileUpload() {
browseButton.move(10, 30);
browseButton.buttonMode = true;
browseButton.label = "Browse";
browseButton.addEventListener(MouseEvent.CLICK, browseHandler);
addChild(browseButton);
uploadButton.move(120,30);
uploadButton.buttonMode=true;
uploadButton.label ="Upload";
uploadButton.addEventListener(MouseEvent.CLICK, uploadHandler);
uploadButton.visible = false;
addChild(uploadButton);
_output = new TextField();
_output.width = 400;
_output.height = 400;
_output.y = 75;
addChild(_output);
_fileReference = new FileReference();
_fileReference.addEventListener(Event.SELECT, selectHandler);
_fileReference.addEventListener(Event.CANCEL, cancelHandler);
_fileReference.addEventListener(ProgressEvent.PROGRESS,progressHandler);
_fileReference.addEventListener(IOErrorEvent.IO_ERROR,ioErrorHandler);
_fileReference.addEventListener(SecurityErrorEvent.SECURITY_ERROR,securityHandler);
_fileReference.addEventListener(Event.COMPLETE, completeHandler);
}
private function browseHandler(event:MouseEvent):void {
_fileReference.browse();
}
private function selectHandler(event:Event):void {
_output.text = "Selected File";
_output.appendText("\nName: " + _fileReference.name);
_output.appendText("\nSize: " + _fileReference.size);
_output.appendText("\nCreated On: " + _fileReference.creationDate);
_output.appendText("\nModified On: " +_fileReference.modificationDate);
uploadButton.visible = true;
}
private function cancelHandler(event:Event):void {
_output.text = "Canceled";
}
private function uploadHandler(event:MouseEvent):void {
_fileReference.upload(new URLRequest("simpleFileUpload.php"));
}
private function progressHandler(event:ProgressEvent):void {
_output.text = "file uploading\noprogress (bytes): " + event.bytesLoaded + " / " + event.bytesTotal;
}
private function ioErrorHandler(event:IOErrorEvent):void {
_output.text = "an IO error occurred";
}
private function securityHandler(event:SecurityErrorEvent):void {
_output.text = "a security error occurred";
}
private function completeHandler(event:Event):void {
_output.text = "the file has uploaded";
uploadButton.visible = false;
}
}
}

PHP

< ? php

move_uploaded_file($_FILES['Filedata']['tmp_name'], 'uploads/'.$_FILES['Filedata']['name']);

Source File - Upload_File.zip

Flash CS3 and PHP - Send and Receive data

2008-06-17T00:04:00.000-07:00

Codes

sendtophp.as
package {
import flash.display.*;
import flash.events.*;
import flash.net.*;
import flash.text.*;
public class sendtophp extends Sprite {
var phpFile:String = "sendDataToServer.php";
public function sendtophp():void {
callBtn.addEventListener(MouseEvent.CLICK, callServer);
}
function callServer(e:MouseEvent):void {
var urlRequest:URLRequest = new URLRequest(phpFile);

var urlParams:URLVariables = new URLVariables();
urlParams.sampleVal = sendTxt.text;

urlRequest.method = URLRequestMethod.POST;
urlRequest.data = urlParams;

var loader:URLLoader = new URLLoader();
loader.addEventListener(Event.COMPLETE, serverResponse);
loader.load(urlRequest);
}
function serverResponse(e:Event):void {
var loader:URLLoader = URLLoader(e.target);
var variables:URLVariables = new URLVariables(loader.data);
responseTxt.text = variables.returnValue;
}
}//end of class sendtophp

}//end of package

sendDataToServer.php
< ? php

print "returnValue= Hi ".$_POST['sampleVal'].", it's working";

?>

Source File - Sending2Server.zip

A Simple Car Animation

2008-04-02T05:40:00.000-07:00

What you see on the stage

What actually happens

We need 6 graphics for this animation

Draw them as shown in the above image (You don’t need to write the name, only graphics)

Now you have 6 graphics on the stage

1. SKY
2. CLOUD
3. LOG
4. CAR BODY
5. TYRE
6. ROAD

Click on Selection Tool (V)

and draw a rectangle around the cloud to select it.

Press F8

You should immediately see a popup dialogue box

Name - cloud
Type – Movie Clip
Registration – Center

Then press OK

See the drawing has been converted to a Movie clip symbol

Do the same steps for

· SKY
· LOG
· CAR BODY
· TYRE
· ROAD

Select the tyre Movie clip with Selection Tool (V)

Press the Alt key and drag the tyre to right side

Release the mouse and Alt key

Now you have two tyres !!!!

Now we are ready for the animation

Arrange car and tyres and select them all (Car and two tyres). (For multiple section use Shift key)

Press F8

Name it car

Now we need a fence like this

Select the log

Press Ctrl+C – (copy)

then Ctrl +Shift+ V (Paste in Place) 22 times

Now you have 22+1 = 23 logs on the stage but still you see just one log because all of them are in the same place.

Select topmost log, drag and place it in the right side of your stage

Press Ctrl+K (window > align)

You don’t need to click on “To stage” this time, if it is already active click on it to deactivate.

Draw a rectangle around all logs with Selection Tool to select them all

In align panel click on distribute horizontal center

See the magic

Select all logs, press F8 and name it fence

Arrange all movie clips

(WORK IN PROGRESS)

Classes

2008-03-31T23:53:00.000-07:00

Classes

Before AS3 you don’t need thorough knowledge in flash to do animations and interactive presentations. But in case of AS3 the scenario is different. Even if you try to learn it from online tutorials you will certainly be blocked by some barriers knows as classes.

This tutorial is only for beginners in AS3 which will explain the functioning of a simple class.

Create a folder named MyClass anywhere in your computer

Create next folder classes as a subfolder of MyClass

Open Adobe Flash CS3 Professional then create a new Flash file (ActionScript 3) and save it as MyFirstClassFile.fla in your MyClass folder

In file menu select New > ActionScript File

Save it as MyFirstClass in your folder MyClass > classes

Now you can see two tabs named MyFirstClassFile.fla and MyFirstClass.as in your window

Select MyFirstClass.as and type the following

package classes{
public class MyFirstClass {
public function MyFirstClass() {
trace("MyFirstClass is working");
}
}
}

back to MyFirstClassFile.fla and type

import classes.MyFirstClass;
var testYourClass:MyFirstClass = new MyFirstClass();

in actions panel

Test the movie (Press CTRL-Enter)

You should immediately get a message traced to the output window saying “MyFirstClass is working”

Download the source file MyClass.zip